Bricked FLORA with Pulse Sensor Amped
Moderators: adafruit_support_bill, adafruit

Please be positive and constructive with your questions and comments.

Bricked FLORA with Pulse Sensor Amped

by caitlinsdad on Thu Mar 21, 2013 10:41 am

1. Has anyone gotten the Pulse Sensor Amped to work with FLORA?

2. My two FLORAs were bricked by loading on the stock pulse monitor sketch and trying to run the Processing software for the heartbeat monitor.
FLORA was working fine(blink) with new IDE on WinXP machine. I then loaded the pulse monitor sketch code only modifying the input data pin 0 for FLORA's 10 and output blink LED to 7, fade LED to 9.
After upload, pulse monitor was lit green so power was good to vbatt and gnd. No red LED light on board when I held the pulse sensor in various positions. I know Pulse sensor is good as it was set up with hot glue/sticker cover and working on an Arduino UNO. I then thought code needed to be modified to try another data input pin or try with 3v low power. I pressed the reset button to see if things would kick off. Few flashes of the red LED, RX LED blinks and then nothing. When I tried to reload a sketch the IDE started complaining there was "No Leonardo to be found". Several attempts have the COM port disappearing and just hanging for a long time to upload until the IDE times out. Trying to press reset after uploading would only make the PC sound off with several "doinks" and give the same pattern of lights.

After several retries of unplugging the FLORA from the USB to reconnect, a few reboots of the PC, the COM port is reestablished. Pressing the reset button on gives the green LED lit constant, 8 fades of the red LED, and a few intermittent flashes of the RX LED.

So, research of the pulse sensor forum did not yield any solutions. The Blinking Series of Death lights on the FLORA was mentioned twice before on the adafruit forums and they mysteriously cleared up. I put my two FLORAs aside for a few days, yup, if it fails on one, brick the other just to make sure. I went back to try to reload the basic blink sketch in an attempt to reset the FLORA. Turning on the verbose mode in the IDE didn't help much since it was only a more cryptic message of no Leonardo found or missing COM port.

On a random try, after watching the verbose mode, when it gets to the repeating COM messages, I was able to press the reset button once, not holding it down for a second, and it seemed to allow it to catch and upload the blink sketch. Yay! Unbricked FLORA. I can brick the FLORA consistently but have not found the exact time to hit the reset as the sketch is trying to upload to unbrick it.

The questions still remain, is the BSOD lights indicative of some diagnostic of the FLORA? Since the pulse sensor uses serial/interrupts to output, did that code lock up the FLORA? Reading into the differences of a Leonardo Aduino, the virtural serial implemented may be incompatible or is not addressed correctly by the code. The IDE failure did have a message resetting COM to 9600 baud. There was some discussion with the 8bit timer on the pulse sensor forum but I don't know what to make of that.

I guess my plans to use the pulse sensor amped wth the FLORA are on hold until the kinks are worked out. Thanks.

btw, I did have that "cr*p, all my stuff is trashed, all that $$$ down the drain" moment but realized, it's cool, this is the bleeding edge of technology.

caitlinsdad
 
Posts: 32
Joined: Fri Feb 24, 2012 4:23 pm

Re: Bricked FLORA with Pulse Sensor Amped

by adafruit_support_bill on Thu Mar 21, 2013 11:10 am

Your Floras are probably not completely bricked. Try pressing the reset button just as the upload is about to start. It will probably take a few tries to hit the timing right, but they usually come around.

adafruit_support_bill
 
Posts: 40177
Joined: Sat Feb 07, 2009 10:11 am

Re: Bricked FLORA with Pulse Sensor Amped

by caitlinsdad on Thu Mar 21, 2013 2:03 pm

Thanks, the FLORAs have recovered. It is hit or miss with the reset button because each time it is pressed, it will cycle the fade/rx blink sequence again.

caitlinsdad
 
Posts: 32
Joined: Fri Feb 24, 2012 4:23 pm

Re: Bricked FLORA with Pulse Sensor Amped

by AEcollin on Fri Mar 22, 2013 12:00 am

I am also experiencing this issue with my Pulse Sensor Amped with the FLORA. I am able to recover using the reset button, but every time I load the Pulse sample code it crashes. Any idea why this is happening?
AEcollin
 
Posts: 1
Joined: Sat Feb 09, 2013 7:42 pm

Re: Bricked FLORA with Pulse Sensor Amped

by caitlinsdad on Sat Mar 30, 2013 6:57 pm

Yay, user alw on posted a fix for the problem of using a pulse sensor amped with the flora. http://pulsesensor.proboards.com/index.cgi?action=display&board=general&thread=173&page=1

Modify the arduino sample sketch code with the following to use a different timer(), comment out or delete the original corresponding timer2 references

Code: Select all | TOGGLE FULL SIZE
TCCR0A = 0x02;
TCCR0B = 0x04; // these put the timer into CTC mode and set the prescaler to 256

OCR0A = 0x7C; // timer0 counts to 124, then gets reset to 0

TIMSK0 = 0x02; // enable interrupt on OCR0A match

//The only other thing you will need is the correct isr vector

ISR(TIMER0_COMPA_vect)

Read more: http://pulsesensor.proboards.com/index. ... z2P4B5HeAH

No more locking up of the Flora when that sketch is uploaded.

caitlinsdad
 
Posts: 32
Joined: Fri Feb 24, 2012 4:23 pm

Re: Bricked FLORA with Pulse Sensor Amped

by tomchambers on Sun Feb 15, 2015 5:44 pm

Could somebody possible post the full sketch including the interruptSetup? I am having trouble getting it to run on my flora.

tomchambers
 
Posts: 9
Joined: Sun Jan 04, 2015 9:47 am

Re: Bricked FLORA with Pulse Sensor Amped

by franklin97355 on Sun Feb 15, 2015 5:49 pm

tomchambers wrote:I am having trouble getting it to run on my flora.

Could you post the code you are trying to use and the troubles it presents?

franklin97355
 
Posts: 9430
Joined: Mon Apr 21, 2008 2:33 pm
Location: Lacomb, OR.

Re: Bricked FLORA with Pulse Sensor Amped

by tomchambers on Sun Feb 15, 2015 5:58 pm

I've used the code from the pulse sensor amped github except for a few lines
Code: Select all | TOGGLE FULL SIZE
pinMode(9, OUTPUT);  digitalWrite(9, HIGH);
to send power to the sensor on pin 9 and the timer interrupt code posted above. I no longer have the issues where it locks up and the serial port disappears, but the light on pin 7 comes on and stays on. Nothing appears in the visualiser either.

The pulse sensor seems to be working, as the light is on, and the analog output voltage fluctuates from 1.6v - 3v.

Code: Select all | TOGGLE FULL SIZE
/*
>> Pulse Sensor Amped 1.2 <<
This code is for Pulse Sensor Amped by Joel Murphy and Yury Gitman
    www.pulsesensor.com
    >>> Pulse Sensor purple wire goes to Analog Pin 0 <<<
Pulse Sensor sample aquisition and processing happens in the background via Timer 2 interrupt. 2mS sample rate.
PWM on pins 3 and 11 will not work when using this code, because we are using Timer 2!
The following variables are automatically updated:
Signal :    int that holds the analog signal data straight from the sensor. updated every 2mS.
IBI  :      int that holds the time interval between beats. 2mS resolution.
BPM  :      int that holds the heart rate value, derived every beat, from averaging previous 10 IBI values.
QS  :       boolean that is made true whenever Pulse is found and BPM is updated. User must reset.
Pulse :     boolean that is true when a heartbeat is sensed then false in time with pin13 LED going out.

This code is designed with output serial data to Processing sketch "PulseSensorAmped_Processing-xx"
The Processing sketch is a simple data visualizer.
All the work to find the heartbeat and determine the heartrate happens in the code below.
Pin 13 LED will blink with heartbeat.
If you want to use pin 13 for something else, adjust the interrupt handler
It will also fade an LED on pin fadePin with every beat. Put an LED and series resistor from fadePin to GND.
Check here for detailed code walkthrough:
http://pulsesensor.myshopify.com/pages/pulse-sensor-amped-arduino-v1dot1

Code Version 1.2 by Joel Murphy & Yury Gitman  Spring 2013
This update fixes the firstBeat and secondBeat flag usage so that realistic BPM is reported.

*/


//  VARIABLES
int pulsePin = 6;                 // Pulse Sensor purple wire connected to analog pin 0
int blinkPin = 7;                // pin to blink led at each beat
int fadePin = 5;                  // pin to do fancy classy fading blink at each beat
int fadeRate = 0;                 // used to fade LED on with PWM on fadePin

// these variables are volatile because they are used during the interrupt service routine!
volatile int BPM;                   // used to hold the pulse rate
volatile int Signal;                // holds the incoming raw data
volatile int IBI = 600;             // holds the time between beats, must be seeded!
volatile boolean Pulse = false;     // true when pulse wave is high, false when it's low
volatile boolean QS = false;        // becomes true when Arduoino finds a beat.


void setup(){
  pinMode(9, OUTPUT);
  digitalWrite(9, HIGH);
  pinMode(blinkPin,OUTPUT);         // pin that will blink to your heartbeat!
  pinMode(fadePin,OUTPUT);          // pin that will fade to your heartbeat!
  Serial.begin(115200);             // we agree to talk fast!
  interruptSetup();                 // sets up to read Pulse Sensor signal every 2mS
   // UN-COMMENT THE NEXT LINE IF YOU ARE POWERING The Arduino at 5V and the Pulse Sensor AT 3V
   // AND APPLY THE LOWER VOLTAGE TO THE A-REF PIN
  //analogReference(EXTERNAL);   
}



void loop(){
  sendDataToProcessing('S', Signal);     // send Processing the raw Pulse Sensor data
  if (QS == true){                       // Quantified Self flag is true when arduino finds a heartbeat
        fadeRate = 255;                  // Set 'fadeRate' Variable to 255 to fade LED with pulse
        sendDataToProcessing('B',BPM);   // send heart rate with a 'B' prefix
        sendDataToProcessing('Q',IBI);   // send time between beats with a 'Q' prefix
        QS = false;                      // reset the Quantified Self flag for next time   
     }
 
  ledFadeToBeat();
 
  delay(20);                             //  take a break
}


void ledFadeToBeat(){
    fadeRate -= 15;                         //  set LED fade value
    fadeRate = constrain(fadeRate,0,255);   //  keep LED fade value from going into negative numbers!
    analogWrite(fadePin,fadeRate);          //  fade LED
  }


void sendDataToProcessing(char symbol, int data ){
    Serial.print(symbol);                // symbol prefix tells Processing what type of data is coming
    Serial.println(data);                // the data to send culminating in a carriage return
  }


Code: Select all | TOGGLE FULL SIZE
volatile int rate[10];                    // array to hold last ten IBI values
volatile unsigned long sampleCounter = 0;          // used to determine pulse timing
volatile unsigned long lastBeatTime = 0;           // used to find IBI
volatile int P =512;                      // used to find peak in pulse wave, seeded
volatile int T = 512;                     // used to find trough in pulse wave, seeded
volatile int thresh = 525;                // used to find instant moment of heart beat, seeded
volatile int amp = 100;                   // used to hold amplitude of pulse waveform, seeded
volatile boolean firstBeat = true;        // used to seed rate array so we startup with reasonable BPM
volatile boolean secondBeat = false;      // used to seed rate array so we startup with reasonable BPM


void interruptSetup(){     
  // Initializes Timer2 to throw an interrupt every 2mS.
//  TCCR2A = 0x02;     // DISABLE PWM ON DIGITAL PINS 3 AND 11, AND GO INTO CTC MODE
//  TCCR2B = 0x06;     // DON'T FORCE COMPARE, 256 PRESCALER
//  OCR2A = 0X7C;      // SET THE TOP OF THE COUNT TO 124 FOR 500Hz SAMPLE RATE
//  TIMSK2 = 0x02;     // ENABLE INTERRUPT ON MATCH BETWEEN TIMER2 AND OCR2A
// 
TCCR0A = 0x02;
TCCR0B = 0x04; // these put the timer into CTC mode and set the prescaler to 256

OCR0A = 0x7C; // timer0 counts to 124, then gets reset to 0

TIMSK0 = 0x02; // enable interrupt on OCR0A match
 
 
  sei();             // MAKE SURE GLOBAL INTERRUPTS ARE ENABLED     
}


// THIS IS THE TIMER 2 INTERRUPT SERVICE ROUTINE.
// Timer 2 makes sure that we take a reading every 2 miliseconds
ISR(TIMER0_COMPA_vect){                         // triggered when Timer2 counts to 124
  cli();                                      // disable interrupts while we do this
  Signal = analogRead(pulsePin);              // read the Pulse Sensor
  sampleCounter += 2;                         // keep track of the time in mS with this variable
  int N = sampleCounter - lastBeatTime;       // monitor the time since the last beat to avoid noise

    //  find the peak and trough of the pulse wave
  if(Signal < thresh && N > (IBI/5)*3){       // avoid dichrotic noise by waiting 3/5 of last IBI
    if (Signal < T){                        // T is the trough
      T = Signal;                         // keep track of lowest point in pulse wave
    }
  }

  if(Signal > thresh && Signal > P){          // thresh condition helps avoid noise
    P = Signal;                             // P is the peak
  }                                        // keep track of highest point in pulse wave

  //  NOW IT'S TIME TO LOOK FOR THE HEART BEAT
  // signal surges up in value every time there is a pulse
  if (N > 250){                                   // avoid high frequency noise
    if ( (Signal > thresh) && (Pulse == false) && (N > (IBI/5)*3) ){       
      Pulse = true;                               // set the Pulse flag when we think there is a pulse
      digitalWrite(blinkPin,HIGH);                // turn on pin 13 LED
      IBI = sampleCounter - lastBeatTime;         // measure time between beats in mS
      lastBeatTime = sampleCounter;               // keep track of time for next pulse

      if(secondBeat){                        // if this is the second beat, if secondBeat == TRUE
        secondBeat = false;                  // clear secondBeat flag
        for(int i=0; i<=9; i++){             // seed the running total to get a realisitic BPM at startup
          rate[i] = IBI;                     
        }
      }

      if(firstBeat){                         // if it's the first time we found a beat, if firstBeat == TRUE
        firstBeat = false;                   // clear firstBeat flag
        secondBeat = true;                   // set the second beat flag
        sei();                               // enable interrupts again
        return;                              // IBI value is unreliable so discard it
      }   


      // keep a running total of the last 10 IBI values
      word runningTotal = 0;                  // clear the runningTotal variable   

      for(int i=0; i<=8; i++){                // shift data in the rate array
        rate[i] = rate[i+1];                  // and drop the oldest IBI value
        runningTotal += rate[i];              // add up the 9 oldest IBI values
      }

      rate[9] = IBI;                          // add the latest IBI to the rate array
      runningTotal += rate[9];                // add the latest IBI to runningTotal
      runningTotal /= 10;                     // average the last 10 IBI values
      BPM = 60000/runningTotal;               // how many beats can fit into a minute? that's BPM!
      QS = true;                              // set Quantified Self flag
      // QS FLAG IS NOT CLEARED INSIDE THIS ISR
    }                       
  }

  if (Signal < thresh && Pulse == true){   // when the values are going down, the beat is over
    digitalWrite(blinkPin,LOW);            // turn off pin 13 LED
    Pulse = false;                         // reset the Pulse flag so we can do it again
    amp = P - T;                           // get amplitude of the pulse wave
    thresh = amp/2 + T;                    // set thresh at 50% of the amplitude
    P = thresh;                            // reset these for next time
    T = thresh;
  }

  if (N > 2500){                           // if 2.5 seconds go by without a beat
    thresh = 512;                          // set thresh default
    P = 512;                               // set P default
    T = 512;                               // set T default
    lastBeatTime = sampleCounter;          // bring the lastBeatTime up to date       
    firstBeat = true;                      // set these to avoid noise
    secondBeat = false;                    // when we get the heartbeat back
  }

  sei();                                   // enable interrupts when youre done!
}// end isr

tomchambers
 
Posts: 9
Joined: Sun Jan 04, 2015 9:47 am

Re: Bricked FLORA with Pulse Sensor Amped

by tomchambers on Mon Feb 16, 2015 7:05 pm

I fixed this issue by using some code which is similar in intention to the above, but different. It's from the official website code guide: http://pulsesensor.com/pages/pulse-sens ... ino-v1dot1

Code: Select all | TOGGLE FULL SIZE
   void interruptSetup(){
        TCCR1A = 0x00;
        TCCR1B = 0x0C;
        OCR1A = 0x7C;
        TIMSK1 = 0x02;
        sei();
    }
 
The only other thing you will need is the correct ISR vector in the next step. ATmega32u4 devices use ISR(TIMER1_COMPA_vect)

tomchambers
 
Posts: 9
Joined: Sun Jan 04, 2015 9:47 am

Please be positive and constructive with your questions and comments.