Controling the 36mm Square RGB LED Pixels - WS2801

[bluegroup]

Hi All,

I'm creating a 6x6 matrix (total36) using the 36mm Square 12V Digital RGB LED Pixels.
I have successfully run the strandtest.pde and it works like a dream.

However I'm stuck on how to control individual squares. For example, lets say I would like an orange "X" and the rest to be blue in the 6x6 matrix.
How would i achieve this or is there a mac controller to do this with? I really would appreciate any help as I'm more of a hardware guy!

[adafruit_support_bill]

Start by numbering all the pixels in your diagram - starting with #0 at the arrow. You can control the color of each pixel with calls to "strip.setPixelColor(i, c)", where 'i' is the pixel number and 'c' is the color. Colors can be set using the "Color(r, g, b)" function where r = red, g = green & b = blue. (You will probably have to experiment a bit to find the right mix of R, G & B to get the colors you want.

For example - to set pixel 0 to orange (I'm guessing at the color mix a little)

Code: Select all

strip.SetPixelColor(0, Color(255, 128, 0));


And to set pixel #1 to blue:

Code: Select all

strip.SetPixelColor(0, Color(0, 0, 255));

Once you have all the pixels colors set, call "strip.show()" to display them on the strip.

[mtbf0]

if you'd like to address your pixels as positions on a cartesian sort of grid, it might be worthwhile to rotate the whole thing so the first pixel is at the upper left with the second pixel to its right and the twelfth pixel below the first, then you could do a calculation along the lines of this...

Code: Select all

  strip.SetPixelColor ((y * 6) + ((y & 1) ? (5 - x) : x), Color(r, g, b));

where y is an int indicating the pixel's row and x is an int indicating it's column. keep in mind that the first row is row 0 and the last row is row 5. same goes for the columns. r, g, and b are ints that indicate the red, green and blue components of the color you want.

[bluegroup]

Thanks for the help guys, I managed to get an "x" using the following bit of code

Code: Select all

void MAKEx()
{
int r = 100;
int g = 100;
int b = 100;
strip.setPixelColor(0,Color(g, r, b));//grd
strip.setPixelColor(5,Color(g, r, b));//grd
strip.setPixelColor(7,Color(g, r, b));//grd
strip.setPixelColor(10,Color(g, r, b));//grd
strip.setPixelColor(14,Color(g, r, b));//grd
strip.setPixelColor(15,Color(g, r, b));//grd
strip.setPixelColor(20,Color(g, r, b));//grd
strip.setPixelColor(21,Color(g, r, b));//grd
strip.setPixelColor(25,Color(g, r, b));//grd
strip.setPixelColor(28,Color(g, r, b));//grd
strip.setPixelColor(30,Color(g, r, b));//grd
strip.setPixelColor(35,Color(g, r, b));//grd
strip.show();
}

Is there a way to make the code better?
I was also wondering how I could fade in and out the "x".

Any advice would be appreciated.

[adafruit_support_rick]

There are a million ways to make the code better. It all depends on what you ultimately want to do with this. Can you give us some idea?

[bluegroup]

I should have said

Is it possible to reduce the amount of code so it doesn't be come too labor intensive.

[adafruit_support_rick]

"Better" and "less labor-intensive" are the same thing. The short answer is that you want to think about patterns.

If you are only going to have a few fixed patterns (for example, if your 'X' is part of a font you're planning to construct), then you want to think about using lookup tables for colors and intensities. You can write a simple loop to pull the pattern's colors and intensities out of one or more tables and write it to the lights. You could have a simple algorithm to do fades and color changes based on the fixed font patterns.

If you want to do some sort of random-looking psychedelic light show, then you want to think about algorithms to generate patterns, mix colors, cycle through different patterns etc.

My rule of thumb for stuff like this is that I want my code to be as simple and stupid as possible. I want to put the smarts into my data structures. Sometimes that takes a little more thought and work up front, but it pays off later on.

[bluegroup]

I would suggest the two below, unfortunately they don't work with the WS2801.
I'm all but giving up on the WS2801 as there's not a lot of support or controllers for them.

Try:
http://pixelinvaders.ch/
http://www.idolstarastronomer.com/char-pixel_paint

[mtbf0]

bluegroup, try this. it compiles, but i don't have a ws2801 strip to test it on. should fade your orange x on a blue background in, hold for a second, then fade the orange to blue. pretty rudimentary.

Code: Select all

#include "SPI.h"
#include "Adafruit_WS2801.h"

#define DATA_LENGTH 36
uint8_t datums[] = {1,0,0,0,0,1,0,1,0,0,1,0,0,0,1,1,0,0,0,1,0,0,1,0,1,0,0,0,0,1};
uint32_t fg, bg;
uint8_t fg_color[] = {0,0,0};
uint8_t bg_color[] = {0,0,0};

Adafruit_WS2801 strip = Adafruit_WS2801(36);

uint32_t Color(uint8_t r, uint8_t g, uint8_t b) {
  uint32_t c;
  c = r;
  c <<= 8;
  c |= g;
  c <<= 8;
  c |= b;
  return c;
}

void display () {
  bg = Color (bg_color[0], bg_color[1], bg_color[2]);
  fg = Color (fg_color[0], fg_color[1], fg_color[2]);
  for (int i = 0; i < DATA_LENGTH; i++) {
    if (datums[i]) strip.setPixelColor(i, fg);
    else strip.setPixelColor(i, bg);
  }
  strip.show ();
}

void fade (int steps, int d) {
  float start[] = {0.0, 0.0, 0.0};
  float end[] = {0.0, 0.0, 0.0};
  float interval[] = {0.0, 0.0, 0.0};
  int i, j;
  for (i = 0; i < 3; i++) {
    start [i] = (float) fg_color[i];
    interval[i] = ((float) bg_color[i] - start[i]) / (float) steps;
  }
  bg = Color (bg_color[0], bg_color[1], bg_color[2]);
  for (j = 1; j < steps; j++) {
    fg = Color ((uint8_t)start[0], (uint8_t)start[1], (uint8_t)start[2]);
    for (int i = 0; i < DATA_LENGTH; i++) {
      if (datums[i]) strip.setPixelColor(i, fg);
    }
    strip.show ();
    start[0] += interval[0];
    start[1] += interval[1];
    start[2] += interval[2];
    delay (d);
  }
  for (int i = 0; i < DATA_LENGTH; i++) {
    if (datums[i]) strip.setPixelColor(i, bg);
  }
  strip.show ();
}

void setup() {
  strip.begin();
  strip.show();
  for (i = 0; i < 128; i++) {
    bg_color[2] += 2;
    fg_color[0] += 2;
    fg_color[1] += 1;
    display ();
    delay (8);
  }
}

void loop () {
  display ();
  delay (1000);
  fade (256, 4);
  delay (1000);
}


[bluegroup]

Thanks mtbf0

I really appreciate the time and effort you have put.
I'll definitely let you know how I go, this sure has given me hope!

[mtbf0]

failed to notice that your strip is grb, so you'll want to change lines like

Code: Select all

  bg = Color (bg_color[0], bg_color[1], bg_color[2]);
  fg = Color (fg_color[0], fg_color[1], fg_color[2]);


to

Code: Select all

  bg = Color (bg_color[1], bg_color[0], bg_color[2]);
  fg = Color (fg_color[1], fg_color[0], fg_color[2]);


fortunately it comes to changing about 8 characters and they're all ones and zeros. without the changes your orange will be kind of gold.

[bluegroup]

Thanks mtbf0,

I had to make a few mods to the code but I did get it working!

Code: Select all

#include "SPI.h"

#include "Adafruit_WS2801.h"

int dataPin  = 2;   
int clockPin = 3;   

Adafruit_WS2801 strip = Adafruit_WS2801(36, dataPin, clockPin);

#define DATA_LENGTH 36

uint8_t datums[] = {1,0,0,0,0,1,0,1,0,0,1,0,0,0,1,1,0,0,0,0,1,1,0,0,0,1,0,0,1,0,1,0,0,0,0,1};

uint32_t fg, bg;

uint8_t fg_color[] = {0,0,0};

uint8_t bg_color[] = {0,0,0};


uint32_t Color(uint8_t r, uint8_t g, uint8_t b) {
  uint32_t c;
  c = r;
  c <<= 8;
  c |= g;
  c <<= 8;
  c |= b;
  return c;
}


void display () {

  bg = Color (bg_color[1], bg_color[0], bg_color[2]);
  fg = Color (fg_color[1], fg_color[0], fg_color[2]);

  for (int i = 0; i < DATA_LENGTH; i++) {

    if (datums[i]) strip.setPixelColor(i, fg);

    else strip.setPixelColor(i, bg);

  }

  strip.show ();

}


void fade (int steps, int d) {

  float start[] = {0.0, 0.0, 0.0};

  float end[] = {0.0, 0.0, 0.0};

  float interval[] = {0.0, 0.0, 0.0};

  int i, j;

  for (i = 0; i < 3; i++) {

    start [i] = (float) fg_color[i];

    interval[i] = ((float) bg_color[i] - start[i]) / (float) steps;

  }

  bg = Color (bg_color[0], bg_color[1], bg_color[2]);

  for (j = 1; j < steps; j++) {

    fg = Color ((uint8_t)start[0], (uint8_t)start[1], (uint8_t)start[2]);

    for (int i = 0; i < DATA_LENGTH; i++) {

      if (datums[i]) strip.setPixelColor(i, fg);

    }

    strip.show ();

    start[0] += interval[0];

    start[1] += interval[1];

    start[2] += interval[2];

    delay (d);

  }

  for (int i = 0; i < DATA_LENGTH; i++) {

    if (datums[i]) strip.setPixelColor(i, bg);

  }

  strip.show ();

}


void setup() {

  strip.begin();

  strip.show();

  for (int i = 0; i < 255; i++) {

   bg_color[2] += 2;

    fg_color[0] += 2;

    fg_color[1] += 1;

    display ();

    delay (8);

  }

}


void loop () {

  display ();

  delay (1000);

  fade (256, 4);

  delay (1000);
   

}

[mtbf0]

I had to make a few mods to the code but I did get it working!

excellent.