Esp8266 temp humidity on adafruit.io using mqtt

Moderators: adafruit_support_bill, adafruit

Forum rules
If you're posting code, please make sure your code does not include your Adafruit IO Active Key or WiFi network credentials.
Locked
User avatar
petran1420
 
Posts: 93
Joined: Fri Jan 08, 2016 9:28 pm

Esp8266 temp humidity on adafruit.io using mqtt

Post by petran1420 »

Tried posting this on an old thread, trying it again as a new topic. I'm working on getting DHT22 temp/humidity data from an esp8266 to adafruit.io. There's not currently an adafruit tutorial for this- there's one for using esp8266 as a temp/humidity webserver that doesn't utilize adafruit.io, and another that utilizes adafruit.io but with an arduino and the older cc3000 model.

I incorporated some reference code from an earlier forum by @theoriginalrage into the adafruit_mqtt esp8266 example. Iget sutck pretty early though- I keep getting an error: 'dht' was not declared in this scope for

Code: Select all

dht.begin(); 
in the setup and

Code: Select all

int humidity_data = (int)dht.readHumidity();
in the loop. I know I uploaded the DHT library correctly because it works just fine in other sketches, even the DHT webserver sketch from adafruit.

I figure its something wrong with my code but I can't seem to find why this sketch is having trouble with DHT commands. Here it is,

Code: Select all

#include <ESP8266WiFi.h>
#include <Adafruit_MQTT.h>
#include <Adafruit_MQTT_Client.h>
#include <DHT.h>

/***************** Define DHT Sensor and access pin **************************/

#define DHTTYPE DHT22
#define DHTPIN  14

/************************* WiFi Access Point *********************************/

#define WLAN_SSID       xxx
#define WLAN_PASS       xxx

/************************* Adafruit.io Setup *********************************/

#define AIO_SERVER      "io.adafruit.com"
#define AIO_SERVERPORT  1883                   // use 8883 for SSL
#define AIO_USERNAME    xxx
#define AIO_KEY         xxx

/************ Global State (you don't need to change this!) ******************/

// Create an ESP8266 WiFiClient class to connect to the MQTT server.
WiFiClient client;
// or... use WiFiFlientSecure for SSL
//WiFiClientSecure client;

// Store the MQTT server, username, and password in flash memory.
// This is required for using the Adafruit MQTT library.
const char MQTT_SERVER[] PROGMEM    = AIO_SERVER;
const char MQTT_USERNAME[] PROGMEM  = AIO_USERNAME;
const char MQTT_PASSWORD[] PROGMEM  = AIO_KEY;

// Setup the MQTT client class by passing in the WiFi client and MQTT server and login details.
Adafruit_MQTT_Client mqtt(&client, MQTT_SERVER, AIO_SERVERPORT, MQTT_USERNAME, MQTT_PASSWORD);

/****************************** Feeds ***************************************/

// Setup feed for light
// Notice MQTT paths for AIO follow the form: <username>/feeds/<feedname>
const char LIGHT_FEED[] PROGMEM = AIO_USERNAME "/feeds/light";
Adafruit_MQTT_Publish light = Adafruit_MQTT_Publish(&mqtt, LIGHT_FEED);

// Setup feed for temp
const char TEMPERATURE_FEED[] PROGMEM = AIO_USERNAME "/feeds/temperature";
Adafruit_MQTT_Publish temperature = Adafruit_MQTT_Publish(&mqtt, TEMPERATURE_FEED);

// Setup feed for humidity
const char HUMIDITY_FEED[] PROGMEM = AIO_USERNAME "/feeds/humidity";
Adafruit_MQTT_Publish humidity = Adafruit_MQTT_Publish(&mqtt, HUMIDITY_FEED);

// Setup a feed called 'onoff' for subscribing to changes.
const char ONOFF_FEED[] PROGMEM = AIO_USERNAME "/feeds/onoff";
Adafruit_MQTT_Subscribe onoffbutton = Adafruit_MQTT_Subscribe(&mqtt, ONOFF_FEED);

/*************************** Sketch Code ************************************/

// Bug workaround for Arduino 1.6.6, it seems to need a function declaration
// for some reason (only affects ESP8266, likely an arduino-builder bug).
void MQTT_connect();

void setup() {

  // Init sensor
  dht.begin();

  
  Serial.begin(115200);
  delay(10);

  Serial.println(F("Adafruit MQTT demo"));

  // Connect to WiFi access point.
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  WiFi.begin(WLAN_SSID, WLAN_PASS);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();

  Serial.println("WiFi connected");
  Serial.println("IP address: "); Serial.println(WiFi.localIP());

  // Setup MQTT subscription for onoff feed.
  mqtt.subscribe(&onoffbutton);
}

uint32_t x=0;

void loop() {
  // Ensure the connection to the MQTT server is alive (this will make the first
  // connection and automatically reconnect when disconnected).  See the MQTT_connect
  // function definition further below.
  MQTT_connect();

  // this is our 'wait for incoming subscription packets' busy subloop
  // try to spend your time here

  Adafruit_MQTT_Subscribe *subscription;
  while ((subscription = mqtt.readSubscription(5000))) {
    if (subscription == &onoffbutton) {
      Serial.print(F("Got: "));
      Serial.println((char *)onoffbutton.lastread);
    }
  }

  // not sure if this is needed
  Serial.print(F("\nSending photocell val "));
  Serial.print(x);
  Serial.print("...");

  // Grab current state of sensors
  int humidity_data = (int)dht.readHumidity();
  int temperature_data = (int)dht.readTemperature();


  // publish
  if (! temperature.publish(temperature_data)) {
    Serial.println(F("Failed to publish temperature"));
  } else {
    Serial.println(F("Temperature published!"));
  }

    if (! humidity.publish(humidity_data)) {
    Serial.println(F("Failed to publish humidity"));
  } else {
    Serial.println(F("Humidity published!"));
  }

  //Repeat every 10 seconds
  delay(10000);


  // ping the server to keep the mqtt connection alive
  // NOT required if you are publishing once every KEEPALIVE seconds
  /*
  if(! mqtt.ping()) {
    mqtt.disconnect();
  }
  */
}

// Function to connect and reconnect as necessary to the MQTT server.
// Should be called in the loop function and it will take care if connecting.
void MQTT_connect() {
  int8_t ret;

  // Stop if already connected.
  if (mqtt.connected()) {
    return;
  }

  Serial.print("Connecting to MQTT... ");

  uint8_t retries = 3;
  while ((ret = mqtt.connect()) != 0) { // connect will return 0 for connected
       Serial.println(mqtt.connectErrorString(ret));
       Serial.println("Retrying MQTT connection in 5 seconds...");
       mqtt.disconnect();
       delay(5000);  // wait 5 seconds
       retries--;
       if (retries == 0) {
         // basically die and wait for WDT to reset me
         while (1);
       }
  }
  Serial.println("MQTT Connected!");
}
Any ideas?

User avatar
chillypenguin
 
Posts: 8
Joined: Fri Apr 01, 2016 7:02 am

Re: Esp8266 temp humidity on adafruit.io using mqtt

Post by chillypenguin »

petran1420 wrote:There's not currently an adafruit tutorial for this
Try this tutorial; Home Automation in the Cloud with the ESP8266 & Adafruit IO

User avatar
jasonfloyd
 
Posts: 1
Joined: Mon Apr 25, 2016 4:29 am

Re: Esp8266 temp humidity on adafruit.io using mqtt

Post by jasonfloyd »

You're missing this line:

Code: Select all

DHT dht(DHTPIN, DHTTYPE);

User avatar
petran1420
 
Posts: 93
Joined: Fri Jan 08, 2016 9:28 pm

Re: Esp8266 temp humidity on adafruit.io using mqtt

Post by petran1420 »

@chillypenguin,

I didn't know that one existed! Thanks for pointing it out!

@jasonfloyd,

Yup, you're right, thanks! I knew it was going to be something small and dumb I couldn't find.

Locked
Forum rules
If you're posting code, please make sure your code does not include your Adafruit IO Active Key or WiFi network credentials.

Return to “Internet of Things: Adafruit IO and Wippersnapper”