Data Logger - How to set the date & time stamp of the log file

[mmathur]

I'm using the Data Logger kit and want to have the correct date and time stamp associated to each of the log files that get created by the Data Logger.

Can you provide any help/direction on how I can set the date and time stamp of the log file when a new file is created? Thank you.

[fat16lib]

Download the latest SdFat here http://code.google.com/p/sdfatlib/downloads/list.

Look at the AnalogLogger.pde example in SdFat/examples. It sets file timestamps.

You should be able to use the same method for your sketch.

SD.h is a wrapper for an old version of SdFat so it may take some mods to the wrapper if you want to use SD.h

[mmathur]

Thanks, I got it working - the log files have the correct date and time stamp.

Here is the code that I used to simply create a file to ensure files get created with the correct date & time stamp:

Code: Select all

#include <SdFat.h>
#include <SdFatUtil.h>  // define FreeRam()
#include <Wire.h>
#include "RTClib.h"

// Serial print stream
ArduinoOutStream cout(Serial);

RTC_DS1307 RTC; // define the Real Time Clock object
//------------------------------------------------------------------------------
// call back for file timestamps
void dateTime(uint16_t* date, uint16_t* time) {
    DateTime now = RTC.now();

  // return date using FAT_DATE macro to format fields
  *date = FAT_DATE(now.year(), now.month(), now.day());

  // return time using FAT_TIME macro to format fields
  *time = FAT_TIME(now.hour(), now.minute(), now.second());
}
//------------------------------------------------------------------------------
// format date/time
ostream& operator << (ostream& os, DateTime& dt) {
  os << dt.year() << '/' << int(dt.month()) << '/' << int(dt.day()) << ',';
  os << int(dt.hour()) << ':' << setfill('0') << setw(2) << int(dt.minute());
  os << ':' << setw(2) << int(dt.second()) << setfill(' ');
  return os;
}

// for the data logging shield, we use digital pin 10 for the SD cs line
const int chipSelect = 10;

// the logging file
ofstream logfile;

//New variable for the SD card
SdFat sd;

// buffer to format data - makes it eaiser to echo to Serial
char buf[80];

void error(char *str)
{
  Serial.print("error: ");
  Serial.println(str);
 
  // red LED indicates error
  //digitalWrite(redLEDpin, HIGH);

  while(1);
}

void setup(void) {
  Serial.begin(9600);
  // make sure that the default chip select pin is set to
  // output, even if you don't use it:
  pinMode(10, OUTPUT);
 
    // pstr stores strings in flash to save RAM
  cout << endl << pstr("FreeRam: ") << FreeRam() << endl;
 
    // format header in buffer
  obufstream bout(buf, sizeof(buf));

  bout << pstr("millis");

  // connect to RTC
  Wire.begin(); 
  if (!RTC.begin()) {
    bout << pstr("RTC failed");
    Serial.println("RTC failed");
  }

  SdFile::dateTimeCallback(dateTime);
  DateTime now = RTC.now();
  cout  << now << endl;
 
  if (!sd.init(SPI_HALF_SPEED, chipSelect)) sd.initErrorHalt(); 
 
  //Get the current time from the Real Time Clock (RTC);
  now = RTC.now();   
 
  // create a new file
  char filename[] = "LOGGER00.CSV";
  for (uint8_t i = 0; i < 100; i++) {
    filename[6] = i/10 + '0';
    filename[7] = i%10 + '0';
    if (sd.exists(filename)) continue;
    logfile.open(filename);
    break;   
  }
 
  if (!logfile.is_open()) {
    Serial.println("Could not create the file!");
    error("couldnt create file");
  }
 
  Serial.print("Logging to: ");
  Serial.println(filename);

  // If you want to set the aref to something other than 5v
  analogReference(EXTERNAL);
}

void loop(void) {

}


[fat16lib]

Looks fine.

One comment about an incantation that is in many programs that use SdFat.

You don't ever need this statement with SdFat:

Code: Select all

  // make sure that the default chip select pin is set to
  // output, even if you don't use it:
  pinMode(10, OUTPUT);

SdFat will do the right thing. What ever the processor is, SS will be set to output mode. This is pin 10 on a 328, pin 53 on a Mega, pin 4 on a Sanguino...

[adafruit]

fat16, agreed. we left that line in because we wanted to remind users about that pin being an output -even if it isnt used- because if its set to an input it breaks everything and people get really confused

[fat16lib]

Explaining which pins are used by a Shield is fine but adding code that is unneeded or wrong in the case of the Mega doesn't seem like a good idea.

Setting pin 10 to output mode causes more problems than it solves. On a Mega it is wrong and if a wire is attached from pin 10 to pin 53, it won't work.

Some people think they should worry about other pins when they see this and do more strange things.

Some think they need to handle chip select.

There is no problem on Adafruit shields, pin 10 is chip select. The Arduino Ethernet shield is fine since 10 is Enet chip select and SdFat lives well with it.

The SparkFun Shield could be a problem since pin 8 is chip select. But they warn users about pin 8, 10.

Since MOSI, MISO, and SCK can be messed up why not set their mode?