LPD8806 Programming

[phil007]

How would I program a color wipe beginning in the center of the LED strip, wiping the new color to both ends?

ColorWipeFromCenter 32 LED strip Example




What about a color chase from the center while running it over a base color?

ColorChaseFromCenter 32 LED strip Example


Thanks,
Phil

[pburgess]

Something close to this should work. Haven't tested, heading out the door to Maker Faire...

Code: Select all

  int i;
  uint32_t c;

  // Set all pixels to red
  c = Color(255, 0, 0);
  for (i=0; i < strip.numPixels(); i++) {
      strip.setPixelColor(i, c);
  }
  strip.show();
  delay(100);

  // Wipe from middle:
  c = Color(255, 255, 255); // white
  for (i=strip.numPixels() / 2 - 1; i >= 0; i--) { // half of strip, count down to 0
    strip.setPixelColor(i, c); // left pixel
    strip.setPixelColor(strip.numPixels() - 1 - i, c); // right pixel
    strip.show();
    delay(100);
  }

[phil007]

I'm missing something here and get the error expected constructor, destructor, or type conversion before '=' token.

Code: Select all

#include "LPD8806.h"
#include "SPI.h"

int dataPin = 2;   
int clockPin = 3;
const int numPixels = 32;

LPD8806 strip = LPD8806(32, dataPin, clockPin);

      int i;
      uint32_t c;


      // Set all pixels to red
      c = Color(255,0,0);
      for (i=0; i < strip.numPixels(); i++) {
          strip.setPixelColor(i, c);
      }
      strip.show();
      delay(100);

      // Wipe from middle:
      c = Color(255, 255, 255); // white
      for (i=strip.numPixels() / 2 - 1; i >= 0; i--) { // half of strip, count down to 0
        strip.setPixelColor(i, c); // left pixel
        strip.setPixelColor(strip.numPixels() - 1 - i, c); // right pixel
        strip.show();
        delay(100);
      }

[adafruit_support_bill]

The code posted by pburgess is not a complete program. It is just an example of how to make colors 'wipe' from the middle.

If you paste that code into your 'void loop()' function it will color the strip red, then wipe white from the middle. You can expand on that by copying the second 'for' loop and changing the colors.

[phil007]

Now the center wipe is working. Thanks for your help.

Phil

Code: Select all

#include "LPD8806.h"
#include "SPI.h"

int dataPin = 2;   
int clockPin = 3;
const int numPixels = 32;

LPD8806 strip = LPD8806(32, dataPin, clockPin);


void setup()

{
  // Start up the LED strip
  strip.begin();
}


void loop() {
  int i;
  uint32_t c;

  c = strip.Color(255, 0, 0); // red
  for (i=strip.numPixels() / 2 - 1; i >= 0; i--) { // half of strip, count down to 0
    strip.setPixelColor(i, c); // left pixel
    strip.setPixelColor(strip.numPixels() - 1 - i, c); // right pixel
    strip.show();
    delay(100);
  }


  c = strip.Color(255, 255, 255); // white
  for (i=strip.numPixels() / 2 - 1; i >= 0; i--) { // half of strip, count down to 0
    strip.setPixelColor(i, c); // left pixel
    strip.setPixelColor(strip.numPixels() - 1 - i, c); // right pixel
    strip.show();
    delay(100);
  }


  c = strip.Color(0, 0, 255); // blue
  for (i=strip.numPixels() / 2 - 1; i >= 0; i--) { // half of strip, count down to 0
    strip.setPixelColor(i, c); // left pixel
    strip.setPixelColor(strip.numPixels() - 1 - i, c); // right pixel
    strip.show();
    delay(100);
  }         


  c = strip.Color(0, 255, 0); // green
  for (i=strip.numPixels() / 2 - 1; i >= 0; i--) { // half of strip, count down to 0
    strip.setPixelColor(i, c); // left pixel
    strip.setPixelColor(strip.numPixels() - 1 - i, c); // right pixel
    strip.show();
    delay(100);
  }           
}



[phil007]

ColorChaseFromCenter is almost working. I'm having an issue with the first LED on right half from center blinking white and the ends of the strip working correctly. See an example in this video. http://www.youtube.com/watch?v=BhmFr-WAhoQ

Do you know what I need to change to correct it?

Code: Select all

void setup()

{
  // Start up the LED strip
  strip.begin();
}

void loop() {
  int i;
  uint32_t c;
  uint32_t b;

  c = strip.Color(200, 200, 200); // white - running color
  b = strip.Color(255, 0, 0); // red - background color
 
  for (i=strip.numPixels() / 2 - 1; i >= 0; i--) { // half of strip, count down to 0
    strip.setPixelColor(i, c); // left pixel
    strip.setPixelColor(i + 1, b); // left pixel
    strip.setPixelColor(strip.numPixels() - 1 - i, c); // right pixel
    strip.setPixelColor(strip.numPixels() - 2 - i, b); // right pixel
    strip.show();
    delay(25);
  }
}

Thanks,
Phil

[adafruit_support_rick]

You want to analyze the math in your loop, I think. Your lights aren't doing what you want at the start and end of the loop. Everything in between seems to work correctly, right?
What you want to do is go through and do the math to see which lights are changed the first time through the loop and then again to see which lights are changed the last time through.

If you've got 32 lights, then the first time thru your loop does this:

i=strip.numPixels() / 2 - 1 = 32/2 - 1 = 15
strip.setPixelColor(i, c); i = 15 -> set 15 to white
strip.setPixelColor(i + 1, b); i + 1 = 16 -> set 16 to red
strip.setPixelColor(strip.numPixels() - 1 - i, c); 32 - 1 - 15 = 16 -> set 16 to white
strip.setPixelColor(strip.numPixels() - 2 - i, b); 32 - 2 - 15 = 15 -> set 15 to red

The last time thru, it does this

i >= 0 = 0
strip.setPixelColor(i, c); i = 0 -> set 0 to white
strip.setPixelColor(i + 1, b); i + 1 = 1 -> set 1 to red
strip.setPixelColor(strip.numPixels() - 1 - i, c); 32 - 1 - 0 = 31 -> set 31 to white
strip.setPixelColor(strip.numPixels() - 2 - i, b); 32 - 2 - 0 = 30 -> set 30 to red

How does this compare with what you're seeing when you run your sketch? With this sort of analysis, you ought to be able to figure out how to modify your loop so it gives you what you want.

[phil007]

I fixed the end of loop error and added an IF statement to fix the second error.

Code: Select all

void loop() {
  int i;
  uint32_t c;
  uint32_t b;

  c = strip.Color(200, 200, 200); // white - running color
  b = strip.Color(255, 0, 0);     // red - background color
 
  for (i=strip.numPixels() / 2 - 1; i >= -1; i--) { // half of strip, count down to 0
    strip.setPixelColor(i, c);     // left pixel
    strip.setPixelColor(i + 1, b); // left pixel
    strip.setPixelColor(strip.numPixels() - 1 - i, c); // right pixel
  if (i < 15) strip.setPixelColor(strip.numPixels() - 2 - i, b); // right pixel
    strip.show();
    delay(25);
  }
}

Thanks for helping me along on learning how to program this strip. I just ordered another 2 meters that will be going on a larger flying wing. This 1 meter strip will be flying after a few more patterns are programmed.

Phil

[adafruit_support_rick]

Flying wing? Cool!