Is there a simple test or tests which can be run on an OLED board to determine if it's faulty? A couple years ago I did the Eye of Newt project using the 1.5 inch OLED and, if I am recalling correctly, the display worked once or twice and then quit. Life intervened and I set it aside until recently.
I removed the OLED and breadboarded it using the circuit and routines described in the discussion at https://learn.adafruit.com/adafruit-1-5 ... g-and-test . Again, the results were negative--the display remains black.
This is a relatively expensive component and I don't want to discard it as faulty just on speculation. I don't know if the fault lies in the display, some other component or my construction. I don't have the knowledge base to come up with any other test procedures on my own
Suggestions would be appreciated.
Is my OLED dead?
Moderators: adafruit_support_bill, adafruit
Please be positive and constructive with your questions and comments.
- mikeysklar
- Posts: 13824
- Joined: Mon Aug 01, 2016 8:10 pm
Re: Is my OLED dead?
Go ahead and post a photo of your wiring and code that you are running in CODE brackets. The only way to figure it out is to walk through the possible issues. If you did any soldering for a header please post a photo of that as well.
- bilagaana
- Posts: 27
- Joined: Sun Dec 10, 2017 2:14 pm
Re: Is my OLED dead?
Thanks for responding.
Below should be a series of images. One shows the original Eye of Newt project with the OLED removed (so that I could run the tutorial linked above, hoping to get some response from the display). As I stated in my initial post, my recollection is that the Eye of Newt worked once or twice, then never again. All code uploaded to the processor would be as provided in that tutorial.
The other two images are of the breadboarded "Adafruit 1.27" and 1.5" Color OLED Breakout Board" tutorial. Again, all code uploaded is per the instructions in that tutorial, in particular the File→Examples→Adafruit_SSD1351→test routine. I did verify the required libraries are installed. I did not proceed beyond that point in the tutorial as no graphics were displayed.
Below should be a series of images. One shows the original Eye of Newt project with the OLED removed (so that I could run the tutorial linked above, hoping to get some response from the display). As I stated in my initial post, my recollection is that the Eye of Newt worked once or twice, then never again. All code uploaded to the processor would be as provided in that tutorial.
The other two images are of the breadboarded "Adafruit 1.27" and 1.5" Color OLED Breakout Board" tutorial. Again, all code uploaded is per the instructions in that tutorial, in particular the File→Examples→Adafruit_SSD1351→test routine. I did verify the required libraries are installed. I did not proceed beyond that point in the tutorial as no graphics were displayed.
- bilagaana
- Posts: 27
- Joined: Sun Dec 10, 2017 2:14 pm
Re: Is my OLED dead?
And here's the complete breadboard assembly:
- mikeysklar
- Posts: 13824
- Joined: Mon Aug 01, 2016 8:10 pm
Re: Is my OLED dead?
Wiring on the breadboard side looks good. I can't make out the controller pin connections on your UNO clone to verify those.
When you upload the code and open a serial console do you see any output?
There is also an option to use the hardware SPI pins which requires commenting out the option1 section at the top of the test code and uncommenting the option #2. Might be worth a try if you re-wire for it. (link and code below)
If you could post a photo of the flex OLED connector (bottom side of the board) so we can verify that it is full seated correctly and locked down.
https://raw.githubusercontent.com/adafr ... t/test.ino
When you upload the code and open a serial console do you see any output?
There is also an option to use the hardware SPI pins which requires commenting out the option1 section at the top of the test code and uncommenting the option #2. Might be worth a try if you re-wire for it. (link and code below)
If you could post a photo of the flex OLED connector (bottom side of the board) so we can verify that it is full seated correctly and locked down.
https://raw.githubusercontent.com/adafr ... t/test.ino
Code: Select all
/***************************************************
This is a example sketch demonstrating graphic drawing
capabilities of the SSD1351 library for the 1.5"
and 1.27" 16-bit Color OLEDs with SSD1351 driver chip
Pick one up today in the adafruit shop!
------> http://www.adafruit.com/products/1431
------> http://www.adafruit.com/products/1673
If you're using a 1.27" OLED, change SCREEN_HEIGHT to 96 instead of 128.
These displays use SPI to communicate, 4 or 5 pins are required to
interface
Adafruit invests time and resources providing this open source code,
please support Adafruit and open-source hardware by purchasing
products from Adafruit!
Written by Limor Fried/Ladyada for Adafruit Industries.
BSD license, all text above must be included in any redistribution
The Adafruit GFX Graphics core library is also required
https://github.com/adafruit/Adafruit-GFX-Library
Be sure to install it!
****************************************************/
// Screen dimensions
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 128 // Change this to 96 for 1.27" OLED.
// You can use any (4 or) 5 pins
#define SCLK_PIN 2
#define MOSI_PIN 3
#define DC_PIN 4
#define CS_PIN 5
#define RST_PIN 6
// Color definitions
#define BLACK 0x0000
#define BLUE 0x001F
#define RED 0xF800
#define GREEN 0x07E0
#define CYAN 0x07FF
#define MAGENTA 0xF81F
#define YELLOW 0xFFE0
#define WHITE 0xFFFF
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1351.h>
#include <SPI.h>
// Option 1: use any pins but a little slower
Adafruit_SSD1351 tft = Adafruit_SSD1351(SCREEN_WIDTH, SCREEN_HEIGHT, CS_PIN, DC_PIN, MOSI_PIN, SCLK_PIN, RST_PIN);
// Option 2: must use the hardware SPI pins
// (for UNO thats sclk = 13 and sid = 11) and pin 10 must be
// an output. This is much faster - also required if you want
// to use the microSD card (see the image drawing example)
//Adafruit_SSD1351 tft = Adafruit_SSD1351(SCREEN_WIDTH, SCREEN_HEIGHT, &SPI, CS_PIN, DC_PIN, RST_PIN);
float p = 3.1415926;
void setup(void) {
Serial.begin(9600);
Serial.print("hello!");
tft.begin();
Serial.println("init");
// You can optionally rotate the display by running the line below.
// Note that a value of 0 means no rotation, 1 means 90 clockwise,
// 2 means 180 degrees clockwise, and 3 means 270 degrees clockwise.
//tft.setRotation(1);
// NOTE: The test pattern at the start will NOT be rotated! The code
// for rendering the test pattern talks directly to the display and
// ignores any rotation.
uint16_t time = millis();
tft.fillRect(0, 0, 128, 128, BLACK);
time = millis() - time;
Serial.println(time, DEC);
delay(500);
lcdTestPattern();
delay(500);
tft.invert(true);
delay(100);
tft.invert(false);
delay(100);
tft.fillScreen(BLACK);
testdrawtext("Lorem ipsum dolor sit amet, consectetur adipiscing elit. Curabitur adipiscing ante sed nibh tincidunt feugiat. Maecenas enim massa, fringilla sed malesuada et, malesuada sit amet turpis. Sed porttitor neque ut ante pretium vitae malesuada nunc bibendum. Nullam aliquet ultrices massa eu hendrerit. Ut sed nisi lorem. In vestibulum purus a tortor imperdiet posuere. ", WHITE);
delay(500);
// tft print function!
tftPrintTest();
delay(500);
//a single pixel
tft.drawPixel(tft.width()/2, tft.height()/2, GREEN);
delay(500);
// line draw test
testlines(YELLOW);
delay(500);
// optimized lines
testfastlines(RED, BLUE);
delay(500);
testdrawrects(GREEN);
delay(1000);
testfillrects(YELLOW, MAGENTA);
delay(1000);
tft.fillScreen(BLACK);
testfillcircles(10, BLUE);
testdrawcircles(10, WHITE);
delay(1000);
testroundrects();
delay(500);
testtriangles();
delay(500);
Serial.println("done");
delay(1000);
}
void loop() {
}
void testlines(uint16_t color) {
tft.fillScreen(BLACK);
for (uint16_t x=0; x < tft.width()-1; x+=6) {
tft.drawLine(0, 0, x, tft.height()-1, color);
}
for (uint16_t y=0; y < tft.height()-1; y+=6) {
tft.drawLine(0, 0, tft.width()-1, y, color);
}
tft.fillScreen(BLACK);
for (uint16_t x=0; x < tft.width()-1; x+=6) {
tft.drawLine(tft.width()-1, 0, x, tft.height()-1, color);
}
for (uint16_t y=0; y < tft.height()-1; y+=6) {
tft.drawLine(tft.width()-1, 0, 0, y, color);
}
tft.fillScreen(BLACK);
for (uint16_t x=0; x < tft.width()-1; x+=6) {
tft.drawLine(0, tft.height()-1, x, 0, color);
}
for (uint16_t y=0; y < tft.height()-1; y+=6) {
tft.drawLine(0, tft.height()-1, tft.width()-1, y, color);
}
tft.fillScreen(BLACK);
for (uint16_t x=0; x < tft.width()-1; x+=6) {
tft.drawLine(tft.width()-1, tft.height()-1, x, 0, color);
}
for (uint16_t y=0; y < tft.height()-1; y+=6) {
tft.drawLine(tft.width()-1, tft.height()-1, 0, y, color);
}
}
void testdrawtext(char *text, uint16_t color) {
tft.setCursor(0,0);
tft.setTextColor(color);
tft.print(text);
}
void testfastlines(uint16_t color1, uint16_t color2) {
tft.fillScreen(BLACK);
for (uint16_t y=0; y < tft.height()-1; y+=5) {
tft.drawFastHLine(0, y, tft.width()-1, color1);
}
for (uint16_t x=0; x < tft.width()-1; x+=5) {
tft.drawFastVLine(x, 0, tft.height()-1, color2);
}
}
void testdrawrects(uint16_t color) {
tft.fillScreen(BLACK);
for (uint16_t x=0; x < tft.height()-1; x+=6) {
tft.drawRect((tft.width()-1)/2 -x/2, (tft.height()-1)/2 -x/2 , x, x, color);
}
}
void testfillrects(uint16_t color1, uint16_t color2) {
tft.fillScreen(BLACK);
for (uint16_t x=tft.height()-1; x > 6; x-=6) {
tft.fillRect((tft.width()-1)/2 -x/2, (tft.height()-1)/2 -x/2 , x, x, color1);
tft.drawRect((tft.width()-1)/2 -x/2, (tft.height()-1)/2 -x/2 , x, x, color2);
}
}
void testfillcircles(uint8_t radius, uint16_t color) {
for (uint8_t x=radius; x < tft.width()-1; x+=radius*2) {
for (uint8_t y=radius; y < tft.height()-1; y+=radius*2) {
tft.fillCircle(x, y, radius, color);
}
}
}
void testdrawcircles(uint8_t radius, uint16_t color) {
for (uint8_t x=0; x < tft.width()-1+radius; x+=radius*2) {
for (uint8_t y=0; y < tft.height()-1+radius; y+=radius*2) {
tft.drawCircle(x, y, radius, color);
}
}
}
void testtriangles() {
tft.fillScreen(BLACK);
int color = 0xF800;
int t;
int w = tft.width()/2;
int x = tft.height();
int y = 0;
int z = tft.width();
for(t = 0 ; t <= 15; t+=1) {
tft.drawTriangle(w, y, y, x, z, x, color);
x-=4;
y+=4;
z-=4;
color+=100;
}
}
void testroundrects() {
tft.fillScreen(BLACK);
int color = 100;
int x = 0;
int y = 0;
int w = tft.width();
int h = tft.height();
for(int i = 0 ; i <= 24; i++) {
tft.drawRoundRect(x, y, w, h, 5, color);
x+=2;
y+=3;
w-=4;
h-=6;
color+=1100;
Serial.println(i);
}
}
void tftPrintTest() {
tft.fillScreen(BLACK);
tft.setCursor(0, 5);
tft.setTextColor(RED);
tft.setTextSize(1);
tft.println("Hello World!");
tft.setTextColor(YELLOW);
tft.setTextSize(2);
tft.println("Hello World!");
tft.setTextColor(BLUE);
tft.setTextSize(3);
tft.print(1234.567);
delay(1500);
tft.setCursor(0, 5);
tft.fillScreen(BLACK);
tft.setTextColor(WHITE);
tft.setTextSize(0);
tft.println("Hello World!");
tft.setTextSize(1);
tft.setTextColor(GREEN);
tft.print(p, 6);
tft.println(" Want pi?");
tft.println(" ");
tft.print(8675309, HEX); // print 8,675,309 out in HEX!
tft.println(" Print HEX!");
tft.println(" ");
tft.setTextColor(WHITE);
tft.println("Sketch has been");
tft.println("running for: ");
tft.setTextColor(MAGENTA);
tft.print(millis() / 1000);
tft.setTextColor(WHITE);
tft.print(" seconds.");
}
void mediabuttons() {
// play
tft.fillScreen(BLACK);
tft.fillRoundRect(25, 10, 78, 60, 8, WHITE);
tft.fillTriangle(42, 20, 42, 60, 90, 40, RED);
delay(500);
// pause
tft.fillRoundRect(25, 90, 78, 60, 8, WHITE);
tft.fillRoundRect(39, 98, 20, 45, 5, GREEN);
tft.fillRoundRect(69, 98, 20, 45, 5, GREEN);
delay(500);
// play color
tft.fillTriangle(42, 20, 42, 60, 90, 40, BLUE);
delay(50);
// pause color
tft.fillRoundRect(39, 98, 20, 45, 5, RED);
tft.fillRoundRect(69, 98, 20, 45, 5, RED);
// play color
tft.fillTriangle(42, 20, 42, 60, 90, 40, GREEN);
}
/**************************************************************************/
/*!
@brief Renders a simple test pattern on the screen
*/
/**************************************************************************/
void lcdTestPattern(void)
{
static const uint16_t PROGMEM colors[] =
{ RED, YELLOW, GREEN, CYAN, BLUE, MAGENTA, BLACK, WHITE };
for(uint8_t c=0; c<8; c++) {
tft.fillRect(0, tft.height() * c / 8, tft.width(), tft.height() / 8,
pgm_read_word(&colors[c]));
}
}
- bilagaana
- Posts: 27
- Joined: Sun Dec 10, 2017 2:14 pm
Re: Is my OLED dead?
I don't claim any expertise in Arduino matters. After uploading the routine to the Arduino clone and pressing the Serial Monitor button, the following appears:
- bilagaana
- Posts: 27
- Joined: Sun Dec 10, 2017 2:14 pm
Re: Is my OLED dead?
Here's the wiring of the Arduino. I notice the perspective makes the GND wire look as if it's one pinout off but I verified it is correct.
Please be positive and constructive with your questions and comments.