0

error: expected unqualified-id before '.' token adafruit dht
Moderators: adafruit_support_bill, adafruit

Please be positive and constructive with your questions and comments.

error: expected unqualified-id before '.' token adafruit dht

by jtech323 on Sun Mar 07, 2021 3:10 pm

Having issues using the adafruit DHT sensor on a mac OS. Here is my code. I posted error below
any help is appreciated!

Code: Select all | TOGGLE FULL SIZE
#include <DHT.h>
#include <DHT_U.h>




//#define dht_apin A0 // Analog pin sensor is connected to

//dht DHT;



void setup() {



Serial.begin(9600);
delay(1000);
Serial.println("DHT11 Humidity & temperature Sensor\n\n");
delay(1000);


}

void loop() {
  // put your main code here, to run repeatedly:


  DHT.read11(dht_apin);

  Serial.print("Current humidity= ");
  Serial.print(DHT.humidity);
  Serial.print("% ");
  Serial.print("temperature = ");
  Serial.print(DHT.temperature);
  Serial.println("C  ");

  delay(2000); // this is equal to 2 seconds but you can change to whatever you want
 

}


Arduino: 1.8.13 (Mac OS X), Board: "Arduino Uno"




/Users/apple/Documents/Arduino/humidity_mar07a/humidity_mar07a.ino: In function 'void loop()':
humidity_mar07a:29:6: error: expected unqualified-id before '.' token
DHT.read11(dht_apin);
^
humidity_mar07a:32:19: error: expected primary-expression before '.' token
Serial.print(DHT.humidity);
^
humidity_mar07a:35:19: error: expected primary-expression before '.' token
Serial.print(DHT.temperature);
^
exit status 1
expected unqualified-id before '.' token


This report would have more information with
"Show verbose output during compilation"
option enabled in File -> Preferences.
Last edited by adafruit_support_bill on Sun Mar 07, 2021 3:45 pm, edited 1 time in total.
Reason: Pleas use [code] tags when posting code to the forums

jtech323
 
Posts: 3
Joined: Sun Mar 07, 2021 3:07 pm

Re: error: expected unqualified-id before '.' token adafruit

by jtech323 on Sun Mar 07, 2021 3:11 pm

Oh also I commented out the

dht DHT;

line to see if it was causing the issue but still getting the error below











/Users/apple/Documents/Arduino/humidity_mar07a/humidity_mar07a.ino: In function 'void loop()':
humidity_mar07a:29:6: error: expected unqualified-id before '.' token
DHT.read11(dht_apin);
^
humidity_mar07a:32:19: error: expected primary-expression before '.' token
Serial.print(DHT.humidity);
^
humidity_mar07a:35:19: error: expected primary-expression before '.' token
Serial.print(DHT.temperature);
^
exit status 1
expected unqualified-id before '.' token

jtech323
 
Posts: 3
Joined: Sun Mar 07, 2021 3:07 pm

Re: error: expected unqualified-id before '.' token adafruit

by adafruit_support_bill on Sun Mar 07, 2021 3:57 pm

Best to start with the example code in the library. The comments explain what you need to edit depending on which type of DHT sensor you are using and what pin it is connected to:


Code: Select all | TOGGLE FULL SIZE
// Example testing sketch for various DHT humidity/temperature sensors
// Written by ladyada, public domain

// REQUIRES the following Arduino libraries:
// - DHT Sensor Library: https://github.com/adafruit/DHT-sensor-library
// - Adafruit Unified Sensor Lib: https://github.com/adafruit/Adafruit_Sensor

#include "DHT.h"

#define DHTPIN 2     // Digital pin connected to the DHT sensor
// Feather HUZZAH ESP8266 note: use pins 3, 4, 5, 12, 13 or 14 --
// Pin 15 can work but DHT must be disconnected during program upload.

// Uncomment whatever type you're using!
#define DHTTYPE DHT11   // DHT 11
//#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor

// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors.  This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(9600);
  Serial.println(F("DHTxx test!"));

  dht.begin();
}

void loop() {
  // Wait a few seconds between measurements.
  delay(2000);

  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius (the default)
  float t = dht.readTemperature();
  // Read temperature as Fahrenheit (isFahrenheit = true)
  float f = dht.readTemperature(true);

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t) || isnan(f)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    return;
  }

  // Compute heat index in Fahrenheit (the default)
  float hif = dht.computeHeatIndex(f, h);
  // Compute heat index in Celsius (isFahreheit = false)
  float hic = dht.computeHeatIndex(t, h, false);

  Serial.print(F("Humidity: "));
  Serial.print(h);
  Serial.print(F("%  Temperature: "));
  Serial.print(t);
  Serial.print(F("°C "));
  Serial.print(f);
  Serial.print(F("°F  Heat index: "));
  Serial.print(hic);
  Serial.print(F("°C "));
  Serial.print(hif);
  Serial.println(F("°F"));
}

adafruit_support_bill
 
Posts: 81287
Joined: Sat Feb 07, 2009 10:11 am

Please be positive and constructive with your questions and comments.