0

Sensor Data not working without Initialisation
Moderators: adafruit_support_bill, adafruit

Please be positive and constructive with your questions and comments.

Sensor Data not working without Initialisation

by Mindkind on Fri Sep 14, 2018 9:39 am

Hi guys,

I am currently developing an IOS app with the Adafruit Feather 32u4 Bluefruit LE and the temperature sensor MCP9808. Everything works well, I can read the temp in real time on my IOS app.

However, each time I disconnect the power (either Micro USB or battery power source) from the 32u4 and I plug it back to turn it on I have to go to the Arduino IDE and then click the Serial Monitor to Initialising the Bluefruit BLE module.

If I dont Initialise, I can connect to the BLE (The blue LED turn on saying im connected), but the BLE isn't taking any data from the sensor and I have no data from temperature sensor.

[EDIT - Sorry I forgot to put the code.. :D]

I removed a line "while (!Serial); // required for Flora & Micro" which seems to work pretty well. But someone can explain me why?

BEFORE
Code: Select all | TOGGLE FULL SIZE
void setup(void)
{
  while (!Serial);  // required for Flora & Micro
  delay(500);


AFTER
Code: Select all | TOGGLE FULL SIZE
void setup(void)
{
  delay(500);


Code: Select all | TOGGLE FULL SIZE
/*********************************************************************
 This is an example for our nRF51822 based Bluefruit LE modules

 Pick one up today in the adafruit shop!

 Adafruit invests time and resources providing this open source code,
 please support Adafruit and open-source hardware by purchasing
 products from Adafruit!

 MIT license, check LICENSE for more information
 All text above, and the splash screen below must be included in
 any redistribution
*********************************************************************/

#include <Arduino.h>
#include <Wire.h>
#include <SPI.h>
#include "Adafruit_BLE.h"
#include "Adafruit_BluefruitLE_SPI.h"
#include "Adafruit_BluefruitLE_UART.h"
#include "Adafruit_MCP9808.h"

#include "BluefruitConfig.h"

#if SOFTWARE_SERIAL_AVAILABLE
  #include <SoftwareSerial.h>
#endif

/*=========================================================================
    APPLICATION SETTINGS

    FACTORYRESET_ENABLE       Perform a factory reset when running this sketch
   
                              Enabling this will put your Bluefruit LE module
                              in a 'known good' state and clear any config
                              data set in previous sketches or projects, so
                              running this at least once is a good idea.
   
                              When deploying your project, however, you will
                              want to disable factory reset by setting this
                              value to 0.  If you are making changes to your
                              Bluefruit LE device via AT commands, and those
                              changes aren't persisting across resets, this
                              is the reason why.  Factory reset will erase
                              the non-volatile memory where config data is
                              stored, setting it back to factory default
                              values.
       
                              Some sketches that require you to bond to a
                              central device (HID mouse, keyboard, etc.)
                              won't work at all with this feature enabled
                              since the factory reset will clear all of the
                              bonding data stored on the chip, meaning the
                              central device won't be able to reconnect.
    MINIMUM_FIRMWARE_VERSION  Minimum firmware version to have some new features
    MODE_LED_BEHAVIOUR        LED activity, valid options are
                              "DISABLE" or "MODE" or "BLEUART" or
                              "HWUART"  or "SPI"  or "MANUAL"
    -----------------------------------------------------------------------*/
    #define FACTORYRESET_ENABLE         1
    #define MINIMUM_FIRMWARE_VERSION    "0.6.6"
    #define MODE_LED_BEHAVIOUR          "MODE"
/*=========================================================================*/

// Create the bluefruit object, either software serial...uncomment these lines
/*
SoftwareSerial bluefruitSS = SoftwareSerial(BLUEFRUIT_SWUART_TXD_PIN, BLUEFRUIT_SWUART_RXD_PIN);

Adafruit_BluefruitLE_UART ble(bluefruitSS, BLUEFRUIT_UART_MODE_PIN,
                      BLUEFRUIT_UART_CTS_PIN, BLUEFRUIT_UART_RTS_PIN);
*/

/* ...or hardware serial, which does not need the RTS/CTS pins. Uncomment this line */
// Adafruit_BluefruitLE_UART ble(BLUEFRUIT_HWSERIAL_NAME, BLUEFRUIT_UART_MODE_PIN);

/* ...hardware SPI, using SCK/MOSI/MISO hardware SPI pins and then user selected CS/IRQ/RST */
Adafruit_BluefruitLE_SPI ble(BLUEFRUIT_SPI_CS, BLUEFRUIT_SPI_IRQ, BLUEFRUIT_SPI_RST);

/* ...software SPI, using SCK/MOSI/MISO user-defined SPI pins and then user selected CS/IRQ/RST */
//Adafruit_BluefruitLE_SPI ble(BLUEFRUIT_SPI_SCK, BLUEFRUIT_SPI_MISO,
//                             BLUEFRUIT_SPI_MOSI, BLUEFRUIT_SPI_CS,
//                             BLUEFRUIT_SPI_IRQ, BLUEFRUIT_SPI_RST);

// Create the MCP9808 temperature sensor object
Adafruit_MCP9808 tempsensor = Adafruit_MCP9808();

// A small helper
void error(const __FlashStringHelper*err) {
  Serial.println(err);
  while (1);
}

/**************************************************************************/
/*!
    @brief  Sets up the HW an the BLE module (this function is called
            automatically on startup)
*/
/**************************************************************************/
void setup(void)
{
  delay(500);

  Serial.begin(9600);
  Serial.println(F("Mindkind BLE"));
  Serial.println(F("------------------------------------------------"));

  /* Initialise the module */
  Serial.print(F("Initialising the Bluefruit LE module: "));

  if ( !ble.begin(VERBOSE_MODE) )
  {
    error(F("Couldn't find Bluefruit, make sure it's in CoMmanD mode & check wiring?"));
  }
  Serial.println( F("OK!") );

  if ( FACTORYRESET_ENABLE )
  {
    /* Perform a factory reset to make sure everything is in a known state */
    Serial.println(F("Performing a factory reset: "));
    if ( ! ble.factoryReset() ){
      error(F("Couldn't factory reset"));
    }
  }

  /* Disable command echo from Bluefruit */
  ble.echo(false);

  Serial.println("Requesting Bluefruit info:");
  /* Print Bluefruit information */
  ble.info();

  // S'assure que le sensor existe et l'initialise
  // Make sure the sensor is found, you can also pass in a different i2c
  // address with tempsensor.begin(0x19) for example
  if (!tempsensor.begin()) {
    Serial.println("Couldn't find MCP9808!");
    while (1);
  }
 
  Serial.println(F("En attente de connection via l'app IOS"));
  Serial.println();

  ble.verbose(false);  // debug info is a little annoying after this point!

  /* Wait for connection */
  while (! ble.isConnected()) {
      delay(500);
  }

  Serial.println(F("******************************"));

  // LED Activity command is only supported from 0.6.6
  if ( ble.isVersionAtLeast(MINIMUM_FIRMWARE_VERSION) )
  {
    // Change Mode LED Activity
    Serial.println(F("Change LED activity to " MODE_LED_BEHAVIOUR));
    ble.sendCommandCheckOK("AT+HWModeLED=" MODE_LED_BEHAVIOUR);
  }

  // Set module to DATA mode
  Serial.println( F("Switching to DATA mode!") );
  ble.setMode(BLUEFRUIT_MODE_DATA);

  Serial.println(F("******************************"));
}

void loop(void)
{
  // mettre int au lieu de float pour obtenir 23 et non pas 23.06
  float c = 0;
  float cc = tempsensor.readTempC();
 
  float f = 0;
  float ff = c * 9.0 / 5.0 + 32;

  // debug
  Serial.print("Temp: "); Serial.print(cc); Serial.print("*C\t");
  Serial.print(ff); Serial.println("*F");

  // Send to Bluefruit
  Serial.print("Sending: ");
  Serial.println(cc);

  // Send input data to host via Bluefruit
  ble.print(cc);

  // Pour envoyer en utilisant le bouton send de la fenetre Serial Monitor
  /*
  if (Serial.available())
  {
  }
  */

  delay(1000);
}


Tanks

Mindkind
 
Posts: 4
Joined: Mon Sep 03, 2018 12:44 pm

Re: Sensor Data not working without Initialisation

by adafruit_support_carter on Fri Sep 14, 2018 2:15 pm

This line of code:
Code: Select all | TOGGLE FULL SIZE
  while (!Serial);  // required for Flora & Micro

will loop forever until the serial monitor is opened.

adafruit_support_carter
 
Posts: 6180
Joined: Tue Nov 29, 2016 2:45 pm

Re: Sensor Data not working without Initialisation

by Mindkind on Fri Sep 14, 2018 2:59 pm

Yes, that's what I figured out while learning a bit more on the Arduino side.

Thanks.

Mindkind
 
Posts: 4
Joined: Mon Sep 03, 2018 12:44 pm

Re: Sensor Data not working without Initialisation

by adafruit_support_carter on Fri Sep 14, 2018 3:14 pm

NP. It trips up a lot of people. So much so that we have it some of our FAQs:
https://learn.adafruit.com/adafruit-fea ... /faq#faq-2

adafruit_support_carter
 
Posts: 6180
Joined: Tue Nov 29, 2016 2:45 pm

Re: Sensor Data not working without Initialisation

by Mindkind on Fri Sep 14, 2018 3:18 pm

Aright I didn't looked at the FAQ.

It doesn't take me too much time to figure it out but I think some people can take hours to find the problem :D

It already took me days to find coding problems so.. It's probably the same for almost every coders ..

Happy coding! ;)

Mindkind
 
Posts: 4
Joined: Mon Sep 03, 2018 12:44 pm

Please be positive and constructive with your questions and comments.