I've got everything working great except none of the 4 control pad functions will loop. The '1' function (larson scanner) loops about 2.5 times, the others loop for no more than 10 seconds.
I want to make all the functions loop until changed - which I figured is what it should do anyways.
I have the Bluefruit with a 32 pixel neopixel strip fyi.
Daft Punk helmet Control Pad functions won't loop
Moderators: adafruit_support_bill, adafruit
Please be positive and constructive with your questions and comments.
- jamoore07
- Posts: 4
- Joined: Sat Sep 16, 2017 1:45 am
- adafruit_support_mike
- Posts: 67485
- Joined: Thu Feb 11, 2010 2:51 pm
Re: Daft Punk helmet Control Pad functions won't loop
Post the code you're using (between CODE tags please), and we'll take a look.
- jamoore07
- Posts: 4
- Joined: Sat Sep 16, 2017 1:45 am
Re: Daft Punk helmet Control Pad functions won't loop
Ok here's the code. This is the exact sketch from the "3D Printed Daft Punk Helmet with Bluetooth" tutorial except my "NUMPIXELS" is 32 instead of 30 like theirs was. I want all 4 functions (1: larsonscanner, 2:colorwipe, etc) to loop.
Code: Select all
/*********************************************************************
This is an example for our nRF51822 based Bluefruit LE modules
Pick one up today in the adafruit shop!
Adafruit invests time and resources providing this open source code,
please support Adafruit and open-source hardware by purchasing
products from Adafruit!
MIT license, check LICENSE for more information
All text above, and the splash screen below must be included in
any redistribution
*********************************************************************/
#include <string.h>
#include <Arduino.h>
#include <SPI.h>
#if not defined (_VARIANT_ARDUINO_DUE_X_) && not defined (_VARIANT_ARDUINO_ZERO_)
#include <SoftwareSerial.h>
#endif
#include "Adafruit_BLE.h"
#include "Adafruit_BluefruitLE_SPI.h"
#include "Adafruit_BluefruitLE_UART.h"
#include "BluefruitConfig.h"
#include <Adafruit_NeoPixel.h>
/*=========================================================================
APPLICATION SETTINGS
FACTORYRESET_ENABLE Perform a factory reset when running this sketch
Enabling this will put your Bluefruit LE module
in a 'known good' state and clear any config
data set in previous sketches or projects, so
running this at least once is a good idea.
When deploying your project, however, you will
want to disable factory reset by setting this
value to 0. If you are making changes to your
Bluefruit LE device via AT commands, and those
changes aren't persisting across resets, this
is the reason why. Factory reset will erase
the non-volatile memory where config data is
stored, setting it back to factory default
values.
Some sketches that require you to bond to a
central device (HID mouse, keyboard, etc.)
won't work at all with this feature enabled
since the factory reset will clear all of the
bonding data stored on the chip, meaning the
central device won't be able to reconnect.
PIN Which pin on the Arduino is connected to the NeoPixels?
NUMPIXELS How many NeoPixels are attached to the Arduino?
-----------------------------------------------------------------------*/
#define FACTORYRESET_ENABLE 1
#define PIN 6
#define NUMPIXELS 32
/*=========================================================================*/
Adafruit_NeoPixel pixel = Adafruit_NeoPixel(NUMPIXELS, 6); // NeoPixel Object for Visor Strips
// Create the bluefruit object, either software serial...uncomment these lines
/*
SoftwareSerial bluefruitSS = SoftwareSerial(BLUEFRUIT_SWUART_TXD_PIN, BLUEFRUIT_SWUART_RXD_PIN);
Adafruit_BluefruitLE_UART ble(bluefruitSS, BLUEFRUIT_UART_MODE_PIN,
BLUEFRUIT_UART_CTS_PIN, BLUEFRUIT_UART_RTS_PIN);
*/
/* ...or hardware serial, which does not need the RTS/CTS pins. Uncomment this line */
// Adafruit_BluefruitLE_UART ble(BLUEFRUIT_HWSERIAL_NAME, BLUEFRUIT_UART_MODE_PIN);
/* ...hardware SPI, using SCK/MOSI/MISO hardware SPI pins and then user selected CS/IRQ/RST */
Adafruit_BluefruitLE_SPI ble(BLUEFRUIT_SPI_CS, BLUEFRUIT_SPI_IRQ, BLUEFRUIT_SPI_RST);
/* ...software SPI, using SCK/MOSI/MISO user-defined SPI pins and then user selected CS/IRQ/RST */
//Adafruit_BluefruitLE_SPI ble(BLUEFRUIT_SPI_SCK, BLUEFRUIT_SPI_MISO,
// BLUEFRUIT_SPI_MOSI, BLUEFRUIT_SPI_CS,
// BLUEFRUIT_SPI_IRQ, BLUEFRUIT_SPI_RST);
// A small helper
void error(const __FlashStringHelper*err) {
Serial.println(err);
while (1);
}
// function prototypes over in packetparser.cpp
uint8_t readPacket(Adafruit_BLE *ble, uint16_t timeout);
float parsefloat(uint8_t *buffer);
void printHex(const uint8_t * data, const uint32_t numBytes);
// the packet buffer
extern uint8_t packetbuffer[];
/**************************************************************************/
/*!
@brief Sets up the HW an the BLE module (this function is called
automatically on startup)
*/
/**************************************************************************/
//additional variables
//Color
uint8_t red = 255;
uint8_t green = 255;
uint8_t blue = 255;
uint8_t animationState = 1;
int pos = 0, dir = 1; // Position, direction of "eye" for larson scanner animation
void setup(void)
{
//while (!Serial); // required for Flora & Micro
delay(500);
// turn off neopixel
pixel.begin(); // This initializes the NeoPixel library.
for(uint8_t i=0; i<NUMPIXELS; i++) {
pixel.setPixelColor(i, pixel.Color(0,0,0)); // off
}
colorWipe(pixel.Color(100, 100, 100), 20);
colorWipe(pixel.Color(0, 0, 0), 20);
pixel.show();
Serial.begin(115200);
Serial.println(F("Adafruit Bluefruit Neopixel Color Picker Example"));
Serial.println(F("------------------------------------------------"));
/* Initialise the module */
Serial.print(F("Initialising the Bluefruit LE module: "));
if ( !ble.begin(VERBOSE_MODE) )
{
error(F("Couldn't find Bluefruit, make sure it's in CoMmanD mode & check wiring?"));
}
Serial.println( F("OK!") );
if ( FACTORYRESET_ENABLE )
{
/* Perform a factory reset to make sure everything is in a known state */
Serial.println(F("Performing a factory reset: "));
if ( ! ble.factoryReset() ){
error(F("Couldn't factory reset"));
}
}
/* Disable command echo from Bluefruit */
ble.echo(false);
Serial.println("Requesting Bluefruit info:");
/* Print Bluefruit information */
ble.info();
Serial.println(F("Please use Adafruit Bluefruit LE app to connect in Controller mode"));
Serial.println(F("Then activate/use the sensors, color picker, game controller, etc!"));
Serial.println();
ble.verbose(false); // debug info is a little annoying after this point!
/* Wait for connection */
while (! ble.isConnected()) {
delay(500);
}
Serial.println(F("***********************"));
// Set Bluefruit to DATA mode
Serial.println( F("Switching to DATA mode!") );
ble.setMode(BLUEFRUIT_MODE_DATA);
Serial.println(F("***********************"));
}
/**************************************************************************/
/*!
@brief Constantly poll for new command or response data
*/
/**************************************************************************/
void loop(void) {
/* Wait for new data to arrive */
uint8_t len = readPacket(&ble, BLE_READPACKET_TIMEOUT);
if (len == 0) return;
/* Got a packet! */
// printHex(packetbuffer, len);
// Color
if (packetbuffer[1] == 'C') {
uint8_t red = packetbuffer[2];
uint8_t green = packetbuffer[3];
uint8_t blue = packetbuffer[4];
Serial.print ("RGB #");
if (red < 0x10) Serial.print("0");
Serial.print(red, HEX);
if (green < 0x10) Serial.print("0");
Serial.print(green, HEX);
if (blue < 0x10) Serial.print("0");
Serial.println(blue, HEX);
for(uint8_t i=0; i<NUMPIXELS; i++) {
pixel.setPixelColor(i, pixel.Color(red,green,blue));
}
pixel.show(); // This sends the updated pixel color to the hardware.
}
// Buttons
if (packetbuffer[1] == 'B') {
uint8_t buttnum = packetbuffer[2] - '0';
boolean pressed = packetbuffer[3] - '0';
Serial.print ("Button "); Serial.print(buttnum);
animationState = buttnum;
if (pressed) {
Serial.println(" pressed");
} else {
Serial.println(" released");
}
if (animationState == 1){
for(uint16_t i=0; i<pixel.numPixels(); i++) {
pixel.setPixelColor(i, pixel.Color(0,0,0));
}
larsonScanner(pixel.Color(255,0,0), 30);
pixel.show(); // This sends the updated pixel color to the hardware.
}
if (animationState == 2){
colorWipe(pixel.Color(100, 0, 0), 20);
colorWipe(pixel.Color(0, 0, 0), 20);
colorWipe(pixel.Color(100, 0, 0), 20);
colorWipe(pixel.Color(0, 0, 0), 20);
colorWipe(pixel.Color(100, 0, 0), 20);
colorWipe(pixel.Color(0, 0, 0), 20);
pixel.show(); // This sends the updated pixel color to the hardware.
}
if (animationState == 3){
for(uint16_t i=0; i<pixel.numPixels(); i++) {
pixel.setPixelColor(i, pixel.Color(0,0,0));
}
pixel.setBrightness(50);
rainbow(10);
pixel.show(); // This sends the updated pixel color to the hardware.
}
if (animationState == 4){
for(uint16_t i=0; i<pixel.numPixels(); i++) {
pixel.setPixelColor(i, pixel.Color(0,0,0));
}
pixel.setBrightness(50);
rainbowCycle(10);
pixel.show(); // This sends the updated pixel color to the hardware.
}
}
}
// Fill the dots one after the other with a color
void colorWipe(uint32_t c, uint8_t wait) {
for(uint16_t i=0; i<pixel.numPixels(); i++) {
pixel.setPixelColor(i, c);
pixel.show();
delay(wait);
}
}
void larsonScanner(uint32_t c, uint8_t wait){
int j;
for(uint16_t i=0; i<pixel.numPixels()+5; i++) {
// Draw 5 pixels centered on pos. setPixelColor() will clip any
// pixels off the ends of the strip, we don't need to watch for that.
pixel.setPixelColor(pos - 2, 0x100000); // Dark red
pixel.setPixelColor(pos - 1, 0x800000); // Medium red
pixel.setPixelColor(pos , 0xFF3000); // Center pixel is brightestF
pixel.setPixelColor(pos + 1, 0x800000); // Medium red
pixel.setPixelColor(pos + 2, 0x100000); // Dark red
pixel.show();
delay(wait);
// Rather than being sneaky and erasing just the tail pixel,
// it's easier to erase it all and draw a new one next time.
for(j=-2; j<= 2; j++) pixel.setPixelColor(pos+j, 0);
// Bounce off ends of strip
pos += dir;
if(pos < 0) {
pos = 1;
dir = -dir;
} else if(pos >= pixel.numPixels()) {
pos = pixel.numPixels() - 2;
dir = -dir;
}
}
//colorWipe(pixel.Color(0, 0, 0), 20);
}
void flashRandom(int wait, uint8_t howmany) {
for(uint16_t i=0; i<howmany; i++) {
// get a random pixel from the list
int j = random(pixel.numPixels());
// now we will 'fade' it in 5 steps
for (int x=0; x < 5; x++) {
int r = red * (x+1); r /= 5;
int g = green * (x+1); g /= 5;
int b = blue * (x+1); b /= 5;
pixel.setPixelColor(j, pixel.Color(r, g, b));
pixel.show();
delay(wait);
}
// & fade out in 5 steps
for (int x=5; x >= 0; x--) {
int r = red * x; r /= 5;
int g = green * x; g /= 5;
int b = blue * x; b /= 5;
pixel.setPixelColor(j, pixel.Color(r, g, b));
pixel.show();
delay(wait);
}
}
// LEDs will be off when done (they are faded to 0)
}
void rainbow(uint8_t wait) {
uint16_t i, j;
for(j=0; j<256; j++) {
for(i=0; i<pixel.numPixels(); i++) {
pixel.setPixelColor(i, Wheel((i+j) & 255));
}
pixel.show();
delay(wait);
}
}
// Slightly different, this makes the rainbow equally distributed throughout
void rainbowCycle(uint8_t wait) {
uint16_t i, j;
for(j=0; j<256*5; j++) { // 5 cycles of all colors on wheel
for(i=0; i< pixel.numPixels(); i++) {
pixel.setPixelColor(i, Wheel(((i * 256 / pixel.numPixels()) + j) & 255));
}
pixel.show();
delay(wait);
}
}
//Theatre-style crawling lights.
void theaterChase(uint32_t c, uint8_t wait) {
for (int j=0; j<10; j++) { //do 10 cycles of chasing
for (int q=0; q < 3; q++) {
for (int i=0; i < pixel.numPixels(); i=i+3) {
pixel.setPixelColor(i+q, c); //turn every third pixel on
}
pixel.show();
delay(wait);
for (int i=0; i < pixel.numPixels(); i=i+3) {
pixel.setPixelColor(i+q, 0); //turn every third pixel off
}
}
}
}
//Theatre-style crawling lights with rainbow effect
void theaterChaseRainbow(uint8_t wait) {
for (int j=0; j < 256; j++) { // cycle all 256 colors in the wheel
for (int q=0; q < 3; q++) {
for (int i=0; i < pixel.numPixels(); i=i+3) {
pixel.setPixelColor(i+q, Wheel( (i+j) % 255)); //turn every third pixel on
}
pixel.show();
delay(wait);
for (int i=0; i < pixel.numPixels(); i=i+3) {
pixel.setPixelColor(i+q, 0); //turn every third pixel off
}
}
}
}
// Input a value 0 to 255 to get a color value.
// The colours are a transition r - g - b - back to r.
uint32_t Wheel(byte WheelPos) {
WheelPos = 255 - WheelPos;
if(WheelPos < 85) {
return pixel.Color(255 - WheelPos * 3, 0, WheelPos * 3);
}
if(WheelPos < 170) {
WheelPos -= 85;
return pixel.Color(0, WheelPos * 3, 255 - WheelPos * 3);
}
WheelPos -= 170;
return pixel.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
}
- adafruit_support_mike
- Posts: 67485
- Joined: Thu Feb 11, 2010 2:51 pm
Re: Daft Punk helmet Control Pad functions won't loop
That code just calls each pattern once, and doesn't check for input again until after the pattern is done.
To adapt it for continuous animation, you'll have to change the way the code handles time. Instead of doing a whole pattern, you'll need functions that update the pixels for one frame of an animation then return. Then you'll need a central loop that checks for input, decides which function to call, and calls the function at the appropriate time.
It will be pretty much a complete rewrite of the code above. These tutorials walk through a discussion of how to write that kind of code though:
https://learn.adafruit.com/multi-taskin ... 1/overview
https://learn.adafruit.com/multi-taskin ... 2/overview
https://learn.adafruit.com/multi-taskin ... 3/overview
To adapt it for continuous animation, you'll have to change the way the code handles time. Instead of doing a whole pattern, you'll need functions that update the pixels for one frame of an animation then return. Then you'll need a central loop that checks for input, decides which function to call, and calls the function at the appropriate time.
It will be pretty much a complete rewrite of the code above. These tutorials walk through a discussion of how to write that kind of code though:
https://learn.adafruit.com/multi-taskin ... 1/overview
https://learn.adafruit.com/multi-taskin ... 2/overview
https://learn.adafruit.com/multi-taskin ... 3/overview
Please be positive and constructive with your questions and comments.