Any ideas are much appreciated!
Below is the Arduino sketch. I removed some of the non-relevant functions (CAN BUS stuff, etc.).
Code: Select all
#include <TinyGPSPlus.h>
#include <Canbus.h>
#include <mcp2515.h>
#include <SD.h>
#include <SoftwareSerial.h>
// GPS
TinyGPSPlus gps;
// Bluetooth
SoftwareSerial ble(2, 3); // RX, TX
int iDataDelay = 10; // delay in Milliseconds used to separate BLE transfers.
const int chipSelect = 9;
int iVoltage;
unsigned long BLEConnectedTimeMillis = 0;
bool BLEConnectedStatus = false;
unsigned long GPSSendBLEMillis;
unsigned long BANNED;
unsigned long RPMMillis;
unsigned long SpeedMillis;
unsigned long LakeTempMillis;
unsigned long DepthMillis;
unsigned long FuelMillis;
unsigned long VoltMillis;
unsigned long LogMillis;
bool ForceSendDepthBLE = true;
bool ForceSendLakeTempBLE = true;
bool ForceSendFuelBLE = true;
bool ForceSendVoltageBLE = true;
bool ForceSendRPMBLE = true;
bool ForceSendSpeedBLE = true;
bool ForceSendGPSMaxBLE = true;
bool ForceSendSatellitesBLE = true;
bool ForceSendGPSBLE = true;
bool ForceSendTripBLE = true;
// Variables for sensors
unsigned char DepthLowByte;
unsigned char DepthHighByte;
unsigned char FuelByte;
unsigned char LakeTempByte;
unsigned char RPMHighByte;
unsigned char RPMLowByte;
unsigned char SpeedHighByte;
unsigned char SpeedLowByte;
int VoltageData;
unsigned int iSatellites;
bool VehicleActive = false;
char cTripLogPathFileName[26];
bool NewLogFileNameCreated = false;
char cDate[10];
char cTime[10];
uint8_t TimeHour;
uint8_t DateDay;
double dblGPSMaxMPH;
double dblGPSMPH;
double dblLat;
double dblLong;
double dblNewLat;
double dblNewLng;
double dblTripA;
double dblTripB;
bool CanBusMonitoringOn = false; // Used to log all CAN bus raw data. Mainly used for debugging or finding new functionality.
void setup() {
// Setup Pin 7 to monitor BLE status
pinMode(7, INPUT);
// Open the serial port. Used for debugging when connected to USB. For normal operation it is used by the GPS.
// GPS TX is connected to RX on UNO board Pin 0. GPS RX is connected to TX on UNO board Pin 1.
// UNO board RX(Pin 0) must be disconnected when uploading a new program to the UNO.
// Switch on custom board flipped away from the GPS Dupont connector disconnects TX pin for uploading a new program.
// Switch on custom board flipped towards the GPS Dupont connector is for normal operation.
Serial.begin(9600);
// Bluetooth serial port communication
ble.begin(9600);
// CAN BUS Shield
pinMode(chipSelect, OUTPUT);
if (!Canbus.init(CANSPEED_250)) {
Serial.println(F("CANFail"));
}
// Init SD Card
if (!SD.begin(chipSelect)) {
ble.print(F("Err!-SI"));
bleNewLnFlushDelay();
Serial.println(F("SDFail"));
}
GPSSendBLEMillis = millis();
RPMMillis = millis();
SpeedMillis = millis();
LakeTempMillis = millis();
DepthMillis = millis();
FuelMillis = millis();
VoltMillis = millis();
LogMillis = millis();
BANNED = millis();
// Read SD card STATS.CSV file to get the last Max GPS speed and the Trip odometer values.
File StatsFile = SD.open("STATS.CSV", FILE_READ);
if (StatsFile) {
dblGPSMaxMPH = StatsFile.readStringUntil(',').toDouble();
dblTripA = StatsFile.readStringUntil(',').toDouble() * 1609.34; // Read Trip A from file and Convert to Meters
dblTripB = StatsFile.readStringUntil(',').toDouble() * 1609.34; // Read Trip B from file and Convert to Meters
StatsFile.close();
SendMaxGPSBLE();
SendTripOdometersBLE();
} else {
ble.print(F("Err!-SS"));
bleNewLnFlushDelay();
Serial.print(F("Err Stats"));
Serial.print(F("\n"));
}
}
void loop() {
// Check for commands from Android App
if (millis() - BANNED > 1000) {
BANNED();
BANNED = millis();
}
// Force send sensor data if new BLE connection.
ForceSendBLEOnNewConnection();
// Fill GPS objects
while (Serial.available() > 0) { gps.encode(Serial.read()); }
if (gps.location.isValid() && gps.satellites.value() > 3) {
dblNewLat = gps.location.lat();
dblNewLng = gps.location.lng();
if (dblNewLat <= 0 or dblNewLng >= 0) { // Check to make sure the location is valid. If not, set it to the previous value.
dblNewLat = dblLat;
dblNewLng = dblLong;
dblGPSMPH = 0;
}
}
// Send GPS related info to Android via BLE
if (millis() - GPSSendBLEMillis >= 300) {
SendGPSInfoBLE();
GPSSendBLEMillis = millis();
}
// Get data from CAN Bus
GetCanBusData();
// Set VehicleActive if vehicle is currently moving.
if (dblGPSMPH >= 1) {
VehicleActive = true;
}
// Get Vehicle Battery Voltage
if (millis() - VoltMillis >= 500) {
GetBatteryVoltage();
VoltMillis = millis();
}
// Trip log
if (millis() - LogMillis >= 800) {
WriteToTripLog();
LogMillis = millis();
}
// Overwrite StatsFile
if (VehicleActive == true and dblGPSMPH < 1) {
WriteToStatsFile();
VehicleActive = false;
}
}
void WriteToStatsFile() {
// Overwrite and store Max GPS Speed and Trip odometers in the STATS.CSV file. This should be written when the vehicle was operating then turned off.
// There is at least 15 seconds of time to write the file from the time the vehicle is stopped and the power is cut off to the UNO.
File StatsFile = SD.open("STATS.CSV", FILE_WRITE | O_TRUNC);
StatsFile.print(dblGPSMaxMPH, 1);
StatsFile.print(",");
StatsFile.print(dblTripA * 0.000621371, 2);
StatsFile.print(",");
StatsFile.print(dblTripB * 0.000621371, 2);
StatsFile.print("\n");
StatsFile.close();
}
void GetBatteryVoltage() {
// Battery voltage measured by UNO board
iVoltage = getVoltage();
if ((iVoltage > VoltageData + 6) or (iVoltage < VoltageData - 6) or ForceSendVoltageBLE == true) { // If voltage changed or ForceSendBLE is true, send to BLE.
ble.write("BattVoltage=");
ble.print(iVoltage);
VoltageData = iVoltage;
bleNewLnFlushDelay();
ForceSendVoltageBLE = false;
}
}
// Function to read the voltage of the battery using A0 analog port (in millivolts).
// Vref = Vmax * (r1/(r1+r2)))
// Actual measurements: Vref = 3.291, r1 = 9990, r2 = 51030
// Using the above formula Vmax = 20.101784
int getVoltage(void) {
int value;
int voltage;
int vDrop = 36; // Voltage drop at Vin Pin on UNO board.
value = analogRead(A0);
voltage = value * (20.101784 / 1023) * 100 + vDrop;
return voltage;
}
void WriteToTripLog() {
// Write a record to the trip log file
if (GPSDateTimeValid()) {
if (NewLogFileNameCreated == false) {
CreateNewLogFileName();
}
ConvertDayAndHourFromUTC();
sprintf(cTime, "%02d:%02d:%02d", TimeHour, gps.time.minute(), gps.time.second());
File TripLogFile = SD.open(cTripLogPathFileName, FILE_WRITE);
if (TripLogFile) {
TripLogFile.print(millis());
TripLogFile.print(",");
TripLogFile.print(cDate);
TripLogFile.print(",");
TripLogFile.print(cTime);
TripLogFile.print(",");
TripLogFile.print(dblNewLat, 6);
TripLogFile.print(",");
TripLogFile.print(dblNewLng, 6);
TripLogFile.print(",");
TripLogFile.print(dblGPSMPH, 1);
TripLogFile.print(",");
TripLogFile.print(dblGPSMaxMPH, 1);
TripLogFile.print(",");
TripLogFile.print(dblTripA * 0.000621371, 2);
TripLogFile.print(",");
TripLogFile.print(dblTripB * 0.000621371, 2);
TripLogFile.print(",");
TripLogFile.print(gps.satellites.value());
TripLogFile.print(",");
TripLogFile.print(VoltageData);
TripLogFile.print(",");
TripLogFile.print(FuelByte);
TripLogFile.print(",");
String strDepth = String(DepthLowByte, HEX);
if (DepthLowByte < 0x10) { strDepth = "0" + strDepth; } // Pad with leading 0 if less than 0x10.
strDepth = String(DepthHighByte, HEX) + strDepth;
float fDepth = strtol(strDepth.c_str(), NULL, 16) / 30.48; // Convert HEX to long and calculate to Feet from Centimeters
if (fDepth > 200) {
TripLogFile.print("");
} else {
TripLogFile.print(fDepth, 1);
}
TripLogFile.print(",");
if (LakeTempByte) {
String strLakeTemp = String(LakeTempByte, HEX);
if (LakeTempByte < 0x10) { strLakeTemp = "0" + strLakeTemp; } // Pad with leading 0 if less than 0x10.
int iLakeTemp = strtol(strLakeTemp.c_str(), NULL, 16) * 1.8 + 32;
TripLogFile.print(iLakeTemp);
}
TripLogFile.print(",");
String strRPM = String(RPMLowByte, HEX);
if (RPMLowByte < 0x10) { strRPM = "0" + strRPM; } // Pad with leading 0 if less than 0x10.
strRPM = String(RPMHighByte, HEX) + strRPM;
int iRPM = strtol(strRPM.c_str(), NULL, 16);
TripLogFile.print(iRPM);
TripLogFile.print("\n");
TripLogFile.close();
} else {
ble.print(F("Err!-SD"));
bleNewLnFlushDelay();
Serial.print(F("ErrSD\n"));
}
}
}
void SendGPSInfoBLE() {
if (gps.location.isValid() && gps.satellites.value() > 3) {
if (iSatellites != gps.satellites.value() or ForceSendSatellitesBLE == true) {
ble.print(F("Sat="));
ble.print(gps.satellites.value());
iSatellites = gps.satellites.value();
bleNewLnFlushDelay();
ForceSendSatellitesBLE = false;
}
if (gps.speed.isValid()) {
double dblTempGPSMPH = gps.speed.mph();
if ((dblTempGPSMPH >= 1) or dblGPSMPH != 0.00 or ForceSendGPSBLE == true) {
dblGPSMPH = dblTempGPSMPH;
if (dblGPSMPH < 1) {
dblGPSMPH = 0;
}
ble.print(F("SpeedGPS="));
ble.print(dblGPSMPH, 1);
bleNewLnFlushDelay();
//Calculate distace traveled for trip odometer
if (dblLat != 0.0 && dblLong != 0.0) {
double dblGPSDistance = gps.distanceBetween(dblLat, dblLong, dblNewLat, dblNewLng);
dblTripA += dblGPSDistance;
dblTripB += dblGPSDistance;
SendTripOdometersBLE();
}
dblLat = dblNewLat;
dblLong = dblNewLng;
ForceSendGPSBLE = false;
}
}
// Update Max GPS MPH
if (dblGPSMPH > dblGPSMaxMPH) {
dblGPSMaxMPH = dblGPSMPH;
SendMaxGPSBLE();
}
} else {
ble.print(F("Sat=0"));
bleNewLnFlushDelay();
ble.print(F("SpeedGPS=0"));
bleNewLnFlushDelay();
}
// Send Max GPS Speed to BLE if ForceSend is set
if (ForceSendGPSMaxBLE == true) {
SendMaxGPSBLE();
ForceSendGPSMaxBLE = false;
}
// Send Trip Odometer data to BLE if ForceSend is set
if (ForceSendTripBLE == true) {
SendTripOdometersBLE();
ForceSendTripBLE = false;
}
}
// Check to see if the time and date returned by the gps function is valid.
// For the year component, the DIY Mall DY-180 GPS module returns 2000 and the
// AdaFruit Ultimate GPS module returns 2080 by default before it sends a valid year.
bool GPSDateTimeValid() {
if (gps.time.isValid() && gps.date.isValid() && gps.date.year() != 2000 && gps.date.year() != 2080) {
return true;
} else {
return false;
}
}
void SendTripOdometersBLE() {
ble.print(F("TripA="));
ble.print(dblTripA * 0.000621371, 2);
bleNewLnFlushDelay();
ble.print(F("TripB="));
ble.print(dblTripB * 0.000621371, 2);
bleNewLnFlushDelay();
}
void SendMaxGPSBLE() {
ble.print(F("MaxGPS="));
ble.print(dblGPSMaxMPH, 1);
bleNewLnFlushDelay();
}
void CreateNewLogFileName() {
char cTimeFileName[10];
ConvertDayAndHourFromUTC();
sprintf(cDate, "%04d%02d%02d", gps.date.year(), gps.date.month(), DateDay);
sprintf(cTimeFileName, "%02d-%02d-%02d", TimeHour, gps.time.minute(), gps.time.second());
if (!SD.exists(cDate)) {
SD.mkdir(cDate);
}
sprintf(cTripLogPathFileName, "/%s/%s.csv", cDate, cTimeFileName);
NewLogFileNameCreated = true;
}
// Convert UTC time to EST(DST)
void ConvertDayAndHourFromUTC() {
TimeHour = gps.time.hour();
DateDay = gps.date.day();
if (TimeHour < 4) {
TimeHour = TimeHour + 20;
if (DateDay > 1) {
DateDay = DateDay - 1;
} else {
DateDay = GetLastDayOfMonth(gps.date.month() - 1);
}
} else {
TimeHour = TimeHour - 4;
}
}
void bleNewLnFlushDelay() {
ble.write("\n");
ble.flush();
delay(iDataDelay);
}
uint8_t GetLastDayOfMonth(short month) {
if (month == 0 || month == 2 || month == 4 || month == 6 || month == 7 || month == 9 || month == 11)
return 31;
else if (month == 3 || month == 5 || month == 8 || month == 10)
return 30;
else
return 28;
}
